ShaderLab學(xué)習(xí)小結(jié)（五）接收平行光陰影

運(yùn)行環(huán)境：
Win10 x64
Unity 5.5.4
在“ShaderLab學(xué)習(xí)小結(jié)（四）簡單產(chǎn)生陰影”基礎(chǔ)上，在頂點(diǎn)片斷著色器中編寫程序使材質(zhì)能接收陰影
將小結(jié)（四）中添加的plane的材質(zhì)換成和球體一樣，即用相同的shader，效果如下：

陰影消失。
球的shader代碼沒有改動(dòng)，也就是說球應(yīng)該是產(chǎn)生陰影了，但是底下的plane也換成球的材質(zhì)，接收不到陰影。
就要修改shader讓它能接收陰影。
Shader代碼：

Shader "Custom/DifSpecPoint" {
    Properties {
        _Spec ("Spec", Color) = (1,1,1,1)
        _Shin ("Shin", range(1,32)) = 2
    }
    SubShader {
        pass {
            tags{ "lightmode" = "forwardbase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "unitycg.cginc"
            #include "lighting.cginc"
            #include "autolight.cginc"  //1.
            #pragma multi_compile_fwdbase //2.
            fixed4 _Spec;
            float _Shin;
            struct v2f{
                float4 pos:POSITION;
                float3 normal:NORMAL;
                float4 vertex:TEXCOORD2;
                SHADOW_COORDS(0)       //3.
            };
            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.normal = normalize(v.normal);
                o.vertex = v.vertex;
                TRANSFER_SHADOW(o)  //4.
                return o;
            }
            fixed4 frag(v2f IN):COLOR
            {
              float3 wpos = mul(unity_ObjectToWorld, IN.vertex).xyz;
                UNITY_LIGHT_ATTENUATION(atten, IN, wpos)  //5.
                //diffuse
                float3 N = UnityObjectToWorldNormal(IN.normal);
                float3 L = normalize(_WorldSpaceLightPos0).xyz;
                float ndotl = saturate(dot(N, L));
                fixed4 col = _LightColor0*ndotl;
                //specular
                float3 V = normalize(WorldSpaceViewDir(IN.vertex));
                float3 R = 2 * dot(N, L)*N - L; //phong
                float3 H = normalize(V + L);    //blinphong
                float specScale = pow(saturate(dot(R, V)), _Shin);  //phong
                specScale = pow(saturate(dot(H, N)), _Shin);        //blinphong
                col += _Spec*specScale;
                //pointlight

                float3 pL = Shade4PointLights(unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0,
                    unity_LightColor[0].rgb, unity_LightColor[1].rgb, unity_LightColor[2].rgb, unity_LightColor[3].rgb,
                    unity_4LightAtten0,
                    wpos, N);
                col.rgb += pL;

                //shadow
                col.rgb *= atten;    //6.

                col += UNITY_LIGHTMODEL_AMBIENT;
                return col;
            }
            ENDCG
        }
    }
        fallback "Diffuse"
}

一、代碼中添加了六處代碼，如上以//1. //2.標(biāo)注

1.

#include "autolight.cginc" //1.

引用autolight.cginc。這里添加的幾處代碼全是在autolight.cginc里定義的，所以很重要。

2.

#pragma multi_compile_fwdbase //2.

添加這一行，見unity手冊“Making multiple shader program variants"中相關(guān)描述： compiles all variants needed by ForwardBase (forward rendering base) pass type. The variants deal with different lightmap types and main directional light having shadows on or off.這會(huì)對應(yīng)主平行光產(chǎn)生的陰影。

以下3~5見autolight.cginc

3.

SHADOW_COORDS(0) //3.

4.

TRANSFER_SHADOW(o) //4.

5.

UNITY_LIGHT_ATTENUATION(atten, IN, wpos) //5.

6.將5中計(jì)算出的atten與顏色的rgb相乘

//shadow
col.rgb *= atten;    //6.

二、

效果如下圖：

可見plane可以接受主平行光照射球體產(chǎn)生的陰影了

1、

從UNITY_LIGHT_ATTENUATION倒推，查看autolight.cginc，在5.0helper中

#ifdef DIRECTIONAL
    #define UNITY_LIGHT_ATTENUATION(destName, input, worldPos)  fixed destName = SHADOW_ATTENUATION(input);
#endif

其中SHADOW_ATTENUATION(input)的定義，查找可知對應(yīng)不同的函數(shù)，但參數(shù)一樣

a._ShadowCoord

再查

_ShadowCoord

在autolight.cginc開頭Shadow helpers中

#define SHADOW_COORDS(idx1) unityShadowCoord4 _ShadowCoord : TEXCOORD##idx1;

定義了，那么在v2f結(jié)構(gòu)體中就要寫入

SHADOW_COORDS(0) //3.

注意括號(hào)里的0，這個(gè)是代表TEXCOORD0，如果0被占了，則依次向后找，比如改成1、2什么的

2.

看

TRANSFER_SHADOW(o) //4.

個(gè)人理解是把計(jì)算的陰影要從vertex程序傳至fragment程序中，然后fragment中的UNITY_LIGHT_ATTENUATION
才能起作用（不信可以把TRANSFER_SHADOW(o)注釋掉，不報(bào)錯(cuò)，但陰影沒了）
而TRANSFER_SHADOW在autolight.cginc中的定義也是需要

a._ShadowCoord

的，所以在v2f結(jié)構(gòu)體中定義了SHADOW_COORDS(0)滿足了TRANSFER_SHADOW和UNITY_LIGHT_ATTENUATION兩段宏的需要。