Unity Shader實(shí)現(xiàn)2D水流效果的方法

Shader "MyUnlit/ScrollWater"
{
 Properties
 {
  _MainTex ("Texture", 2D) = "white" {}
  _Color("Color Tint",color)=(1,1,1,1)
  //控制水流波動(dòng)的幅度，也就是三角函數(shù)中的振幅（值域范圍）
  _Magnitude("Distortion Magnitude",float)=0.3
  //控制周期的長(zhǎng)度，值越大，周期越短，頻率越高
  _InvWaveLength("Distortion Inserve Wave Length",float)=1
  //流動(dòng)速度，用于紋理變換
  _Speed("Speed",float)=0.1
 }
 SubShader
 {
  //頂點(diǎn)動(dòng)畫(huà)需要禁用合P處理
  Tags {"Queue"="Transparent" "RenderType"="Transparent" "IgnoreProjector"="true" "DisableBatching"="True"}

  Pass
  {
   //透明度混合：關(guān)閉深度寫(xiě)入+設(shè)置混合狀態(tài)+禁用剔除（雙面渲染）
   Tags{"lightmode"="forwardbase"}
   ZWrite off
   Blend SrcAlpha OneMinusSrcAlpha
   Cull off

   CGPROGRAM
   #pragma vertex vert
   #pragma fragment frag
   #pragma multi_compile_fog

   #include "UnityCG.cginc"
   struct appdata
   {
    float4 vertex : POSITION;
    float2 uv : TEXCOORD0;
   };

   struct v2f
   {
    float2 uv : TEXCOORD0;
    UNITY_FOG_COORDS(1)
    float4 vertex : SV_POSITION;
   };

   sampler2D _MainTex;
   float4 _MainTex_ST;
   fixed4 _Color;
   float _Magnitude;
   float _InvWaveLength;
   float _Speed;

   v2f vert (appdata v)
   {
    v2f o;
    float4 offset;
    //這里的方向可以自己選擇，這里選擇偏移x方向，其他方向的偏移保持不變
    offset.yzw = float3(0, 0, 0);
    //利用正弦函數(shù)模擬河流整體的形狀，最后乘以振幅
    offset.x = sin((v.vertex.x + v.vertex.y + v.vertex.z)*_InvWaveLength)*_Magnitude;
    o.vertex = UnityObjectToClipPos(v.vertex+offset);
    //對(duì)uv進(jìn)行某一方向的滾動(dòng)以模擬水流，這里選擇v向
    o.uv = TRANSFORM_TEX(v.uv, _MainTex);
    o.uv += float2(0.0, _Time.y*_Speed);

    UNITY_TRANSFER_FOG(o,o.vertex);
    return o;
   }

   fixed4 frag (v2f i) : SV_Target
   {
    fixed4 col = tex2D(_MainTex, i.uv);
    col.rgb *= _Color.rgb;
    UNITY_APPLY_FOG(i.fogCoord, col);
    return col;
   }
   ENDCG
  }
 }
 FallBack "Transparent/VertexLit"
}