怎么在易語言中通過post操作的小米路由器

本篇文章給大家分享的是有關(guān)怎么在易語言中通過post操作的小米路由器，小編覺得挺實用的，因此分享給大家學(xué)習(xí)，希望大家閱讀完這篇文章后可以有所收獲，話不多說，跟著小編一起來看看吧。

操作小米路由器的代碼

此功能需要加載精易模塊5.6

.版本 2
.支持庫 iext2
.程序集 窗口程序集_啟動窗口
.程序集變量 IP, 文本型
.程序集變量 cookie, 文本型
.程序集變量 token, 文本型
.子程序 登錄, 文本型
.參數(shù) 密碼, 文本型
.參數(shù) 返回內(nèi)容, 文本型, 參考
.參數(shù) token, 文本型, 參考
.局部變量 臨時, 文本型
.局部變量 deviceId, 文本型
.局部變量 key, 文本型
.局部變量 時間戳, 文本型
.局部變量 隨機數(shù), 文本型
.局部變量 psw, 文本型
.局部變量 nonce, 文本型
.局部變量 密碼加密, 文本型
.局部變量 nonce編碼, 文本型
臨時 ＝ 網(wǎng)頁_訪問S (“http://” ＋ IP ＋ “/cgi-bin/luci/web”)
deviceId ＝ 文本_取出中間文本 (臨時, “deviceId = '”, “'”)
key ＝ 文本_取出中間文本 (臨時, “key: '”, “'”)
時間戳 ＝ 時間_到時間戳 (, 真)
隨機數(shù) ＝ 文本_取隨機范圍數(shù)字 (1000, 9999)
psw ＝ 密碼
nonce ＝ “0_” ＋ deviceId ＋ “_” ＋ 時間戳 ＋ “_” ＋ 隨機數(shù)
密碼加密 ＝ 校驗_取sha1 (到字節(jié)集 (nonce ＋ 校驗_取sha1 (到字節(jié)集 (psw ＋ key))))
增加日志 (“key:” ＋ #換行符 ＋ key)
增加日志 (“nonce:” ＋ #換行符 ＋ nonce)
增加日志 (“nonce編碼:” ＋ #換行符 ＋ nonce編碼)
返回內(nèi)容 ＝ 網(wǎng)頁_訪問S (“http://” ＋ IP ＋ “/cgi-bin/luci/api/xqsystem/login”, 1, “username=admin&password=” ＋ 密碼加密 ＋ “&logtype=2&nonce=” ＋ nonce, , cookie, , , 真)
token ＝ 文本_取出中間文本 (返回內(nèi)容, “token” ＋ #引號 ＋ “:” ＋ #引號, #引號)
.如果真 (尋找文本 (返回內(nèi)容, #引號 ＋ “code” ＋ #引號 ＋ “:0”, , 假) ＝ -1)
  返回 (“失敗”)
.如果真結(jié)束
返回 (“成功”)
.子程序 增加日志
.參數(shù) 日志內(nèi)容, 文本型
日志編輯框.加入文本 (日志內(nèi)容 ＋ #換行符 ＋ “------------------------------------------------------------------------” ＋ #換行符)
.子程序 _登陸按鈕_被單擊
.局部變量 返回, 文本型
.局部變量 返回內(nèi)容, 文本型
.局部變量 psw, 文本型
IP ＝ IP編輯框.地址
psw ＝ 密碼編輯框.內(nèi)容
token ＝ “”
.如果真 (IP ＝ “” 或 psw ＝ “”)
  信息框 (“IP或密碼不能為空”, 0, )
  返回 ()
.如果真結(jié)束
返回 ＝ 登錄 (psw, 返回內(nèi)容, token)
.判斷開始 (返回 ＝ “成功”)
  增加日志 (“登陸成功:” ＋ #換行符 ＋ 返回內(nèi)容)
  增加日志 (“token:” ＋ #換行符 ＋ token)
.默認(rèn)
  增加日志 (“登錄失敗:” ＋ #換行符 ＋ 返回內(nèi)容)
.判斷結(jié)束
.子程序 _斷開按鈕_被單擊
.局部變量 返回, 文本型
.如果真 (token ＝ “”)
  信息框 (“請先登錄”, 0, )
  返回 ()
.如果真結(jié)束
返回 ＝ 網(wǎng)頁_訪問S (“http://” ＋ IP ＋ “/cgi-bin/luci/;stok=” ＋ token ＋ “/api/xqnetwork/pppoe_stop”)
.判斷開始 (尋找文本 (返回, #引號 ＋ “code” ＋ #引號 ＋ “:0”, , 假) ＝ -1)
  增加日志 (“斷網(wǎng)失敗:” ＋ #換行符 ＋ 返回)
.默認(rèn)
  增加日志 (“斷網(wǎng)成功:” ＋ #換行符 ＋ 返回)
.判斷結(jié)束
.子程序 _撥號按鈕_被單擊
.局部變量 返回, 文本型
.如果真 (token ＝ “”)
  信息框 (“請先登錄”, 0, )
  返回 ()
.如果真結(jié)束
返回 ＝ 網(wǎng)頁_訪問S (“http://” ＋ IP ＋ “/cgi-bin/luci/;stok=” ＋ token ＋ “/api/xqnetwork/pppoe_start”)
.判斷開始 (尋找文本 (返回, #引號 ＋ “code” ＋ #引號 ＋ “:0”, , 假) ＝ -1)
  增加日志 (“撥號失敗:” ＋ #換行符 ＋ 返回)
.默認(rèn)
  增加日志 (“撥號成功:” ＋ #換行符 ＋ 返回)
.判斷結(jié)束

運行結(jié)果：

以上就是怎么在易語言中通過post操作的小米路由器，小編相信有部分知識點可能是我們?nèi)粘９ぷ鲿姷交蛴玫降?。希望你能通過這篇文章學(xué)到更多知識。更多詳情敬請關(guān)注億速云行業(yè)資訊頻道。