drools中then部分怎么寫

這篇文章主要介紹“drools中then部分怎么寫”的相關知識，小編通過實際案例向大家展示操作過程，操作方法簡單快捷，實用性強，希望這篇“drools中then部分怎么寫”文章能幫助大家解決問題。

1、背景

此處介紹一下drools中then部分的寫法，以及一些內(nèi)置的方法，比如insert/delete/modify等等。同時也介紹一下rule的繼承，和在when中實現(xiàn)if else if 等操作。

2、支持的方法

drools提供了一些內(nèi)置的方法，這些方法會修改drools的工作內(nèi)存中Fact對象的值。從而會導致重新進行模式匹配。

2.1 insert 插入對象到工作內(nèi)存中

insert是向工作內(nèi)存中插入對象，同時會導致重新進行規(guī)則的模式匹配。同時當規(guī)則不滿足時，不會自動刪除。

2.1.1 需求

當發(fā)生火災Fire時，向工作內(nèi)存中插入一個Alarm對象，告警發(fā)生后，刪除工作內(nèi)存中的Fire對象，然后檢測Alarm對象是否還存在。

2.1.2 drl文件編寫

package rules
import com.huan.drools.insertmethod.Fire
import com.huan.drools.insertmethod.Alarm
rule "insert_發(fā)生火災時，往工作內(nèi)存中插入告警對象"
    when
        $fire: Fire()
    then
        System.out.println("1、發(fā)生火災時，往工作內(nèi)存中插入告警對象");
        insert(new Alarm($fire));
end
rule "insert_當規(guī)則內(nèi)存中存在告警對象，進行告警，然后刪除火災對象"
    when
        $fire: Fire()
        $alarm: Alarm( fire == $fire )
    then
        System.out.println("2、進行告警，然后刪除對應的火災對象");
end
rule "insert_檢測告警對象是否還是存在-01"
    when
        Alarm()
    then
        System.out.println("3、insert 插入的告警對象還存在");
        // 刪除工作內(nèi)存中的Fire對象
        delete($fire);
end
rule "insert_檢測告警對象不存在"
    when
        not Alarm()
    then
        System.out.println("3、insert 插入的告警對象不存在");
end

此處使用的是 insert進行插入

2.1.3 部分java代碼編寫

// 將火災對象插入到工作內(nèi)存中
kieSession.insert(new Fire());
// 只觸發(fā)規(guī)則名稱以 insert_ 開頭的規(guī)則
kieSession.fireAllRules(new RuleNameStartsWithAgendaFilter("insert_"));

2.1.4 運行結(jié)果

1、發(fā)生火災時，往工作內(nèi)存中插入告警對象
2、進行告警，然后刪除對應的火災對象
3、insert 插入的告警對象還存在

2.1.5 結(jié)論

• insert可以向工作內(nèi)存中插入Fact對象。

• insert方法調(diào)用后，會導致模式的重新匹配，導致之前不會執(zhí)行的規(guī)則，重新執(zhí)行。

• insert方法插入到工作內(nèi)存的對象，在規(guī)則不成立時，不會自動刪除，需要手動刪除，注意和insertLogical的區(qū)別

2.2 insertLogical 插入對象到工作內(nèi)存中

insert是向工作內(nèi)存中插入對象，同時會導致重新進行規(guī)則的模式匹配。同時當規(guī)則不滿足時，會自動刪除。

2.2.1 需求

當發(fā)生火災Fire時，向工作內(nèi)存中插入一個Alarm對象，告警發(fā)生后，刪除工作內(nèi)存中的Fire對象，然后檢測Alarm對象是否還存在。

2.2.2 drl文件編寫

package rules
import com.huan.drools.Fire
import com.huan.drools.Alarm
rule "insertLogical_發(fā)生火災時，往工作內(nèi)存中插入告警對象"
    when
        $fire: Fire()
    then
        System.out.println("1、發(fā)生火災時，往工作內(nèi)存中插入告警對象");
        insertLogical(new Alarm($fire));
end
rule "insertLogical_當規(guī)則內(nèi)存中存在告警對象，進行告警，然后刪除火災對象"
    when
        $fire: Fire()
        $alarm: Alarm( fire == $fire )
    then
        System.out.println("2、進行告警，然后刪除對應的火災對象");
        delete($fire);
end
rule "insertLogical_檢測告警對象是否還是存在-01"
    when
        Alarm()
    then
        System.out.println("3、insertLogical 插入的告警對象還存在");
end
rule "insertLogical_檢測告警對象不存在"
    when
        not Alarm()
    then
        System.out.println("3、insertLogical 插入的告警對象不存在");
end

此處使用的是insertLogical插入

2.2.3 部分java代碼編寫

kieSession.insert(new Fire());
kieSession.fireAllRules(new RuleNameStartsWithAgendaFilter("insertLogical_"));

2.2.4 運行結(jié)果

1、發(fā)生火災時，往工作內(nèi)存中插入告警對象
2、進行告警，然后刪除對應的火災對象
3、insertLogical 插入的告警對象不存在

2.2.5 結(jié)論

1. insertLogical可以向工作內(nèi)存中插入Fact對象。

2. insertLogical方法調(diào)用后，會導致模式的重新匹配，導致之前不會執(zhí)行的規(guī)則，重新執(zhí)行。

3. insertLogical方法插入到工作內(nèi)存的對象，在規(guī)則不成立時，會自動刪除注意和insert的區(qū)別

2.3、update 更新工作內(nèi)存中的對象

update: 使用它來指定要更新的字段和整個相關Fact，并將更改通知 Drools 引擎。 Fact發(fā)生更改后，您必須在更改可能受更新值影響的另一個事實之前調(diào)用 update。 為避免此添加步驟，請改用 modify 方法。

2.3.1 需求

規(guī)則一： 當工作內(nèi)存中存在火災對象Fire，并且名字name為空時觸發(fā)規(guī)則，同時在設置火災的名字為大火災。
規(guī)則二： 當火災存在名字時，輸出火災名字

2.3.2 drl 文件編寫

package rules
import com.huan.drools.Fire
import com.huan.drools.Alarm
rule "update_當存在火災對象時，設置一個火災的名字"
    when
        $fire: Fire(name == null)
    then
        System.out.println("1、設置火災名字");
        $fire.setName("大火災");
        update($fire)
end
rule "update_當火災對象存在名字時觸發(fā)"
    when
        $fire: Fire(name != null)
    then
        System.out.println("2、火災對象的名字為: " + $fire.getName());
end

2.3.3 部分java文件編寫

kieSession.insert(new Fire());
kieSession.fireAllRules(new RuleNameStartsWithAgendaFilter("update_"));

2.3.4 運行結(jié)果

1、設置火災名字
2、火災對象的名字為: 大火災

2.3.4 結(jié)論

• update會導致模式的重新匹配。

• update會修改工作對象內(nèi)存中的值。

2.4、modify 更新工作內(nèi)存中的對象

modify： 使用它來指定要為Fact對象修改的字段并將更改通知 Drools 引擎。 此方法提供了一種結(jié)構(gòu)化的事實更新方法。 它將更新操作與 setter 調(diào)用相結(jié)合以更改對象字段。

2.4.1 需求

規(guī)則一： 當工作內(nèi)存中存在火災對象Fire，并且名字name為空時觸發(fā)規(guī)則，同時在設置火災的名字為大火災。
規(guī)則二： 當火災存在名字時，輸出火災名字

2.4.2 drl 文件編寫

package rules
import com.huan.drools.Fire
import com.huan.drools.Alarm
rule "modify_當存在火災對象時，設置一個火災的名字"
    when
        $fire: Fire(name == null)
    then
        System.out.println("1、設置火災名字");
        modify($fire){
            setName("大火災")
        }
end
rule "modify_當火災對象存在名字時觸發(fā)"
    when
        $fire: Fire(name != null)
    then
        System.out.println("2、火災對象的名字為: " + $fire.getName());
end

2.4.3 部分java文件編寫

kieSession.insert(new Fire());
kieSession.fireAllRules(new RuleNameStartsWithAgendaFilter("modify_"));

2.4.4 運行結(jié)果

• 1、設置火災名字

• 2、火災對象的名字為: 大火災

2.4.5 結(jié)論

• modify會導致模式的重新匹配。

• modify會修改工作對象內(nèi)存中的值。一般情況下使用modify，不要使用update。

2.5 delete 刪除工作內(nèi)存中的對象

用法：delete(<object>)

retract也是和delete一樣的效果，但是推薦使用delete。

3、drools變量的簡單使用

package rules
rule "drools_變量的使用"
    wh
        eval(true)
    then
        System.out.println("Match激活的當前觸發(fā)規(guī)則: " + drools.getMatch());
        System.out.println("當前觸發(fā)規(guī)則的名字: " + drools.getRule().getName());
        // System.out.println("終止規(guī)則執(zhí)行fireUntilHalt(): " + drools.getKieRuntime().halt());
        // System.out.println("激活AgendaGroup組: " + drools.getKieRuntime().getAgenda().getAgendaGroup( "CleanUp" ).setFocus());
        System.out.println("獲取所有全局變量: " + drools.getKieRuntime().getGlobals());
        // System.out.println("設置全局變量：" +  drools.getKieRuntime().setGlobal("username","huan"); );
        // System.out.println("獲取查詢結(jié)果：" + drools.getKieRuntime().getQueryResults());
end

4、規(guī)則的繼承

4.1 需求

規(guī)則一： 如果用戶(customer)的年齡(age)大于60歲，則打0.9折。
規(guī)則二： 在規(guī)則一的基礎上，如果用戶有車(car)，則可以免費停車(freeParking)。

4.2 drl文件編寫

package rules
import com.huan.drools.Customer
import com.huan.drools.Car
rule "rule_extends_規(guī)則一"
    when
        $c: Customer(age > 60)
    then
        modify($c){
            setDiscount(0.9)
        }
        System.out.println("觸發(fā)規(guī)則一：用戶年齡>60歲，打0.9折");
end
// 規(guī)則二繼承規(guī)則一的條件
rule "rule_extends_規(guī)則二" extends "rule_extends_規(guī)則一"
    when
        $car: Car()
    then
        modify($car){
            setFreeParking(true)
        }
        System.out.println("觸發(fā)規(guī)則二：用戶有車，免費停車");
end

此處rule_extends_規(guī)則二繼承了rule_extends_規(guī)則一，所以規(guī)則一的條件也繼承了。

4.3 部分java代碼

Car car = new Car();
Customer customer = new Customer();
customer.setAge(65);
kieSession.insert(customer);
kieSession.insert(car);
kieSession.fireAllRules(new RuleNameStartsWithAgendaFilter("rule_extends_"));

客戶有車，并且年齡是65歲，滿足上方的規(guī)則一和規(guī)則二

4.4 運行結(jié)果

觸發(fā)規(guī)則一：用戶年齡>60歲，打0.9折
觸發(fā)規(guī)則二：用戶有車，免費停車

4.5 結(jié)論

可以看到在rule上使用extends關鍵字，可以實現(xiàn)規(guī)則的繼承。

5、使用do[...]語法重寫上方繼承的例子

5.1 需求

只要用戶大于60歲，直接打0.9折，如果還有車，則可以免費停車。

5.2 drl文件編寫

package rules
import com.huan.drools.Customer
import com.huan.drools.Car
rule "命名結(jié)果_rule"
    when
        $c: Customer(age > 60)
        do[giveDiscount] // 當上方的條件成立時執(zhí)行 then [giveDiscount]
        $car: Car() // 此條件成立時，執(zhí)行默認的 then
    then
        modify($car){
            setFreeParking(true)
        };
        System.out.println("用戶有車，免費停車");
    then [giveDiscount]
        modify($c){
            setDiscount(0.9)
        };
        System.out.println("用戶年齡>60歲，打0.9折");
end

解釋： 見上方的規(guī)則文件里的注視

5.3 部分java代碼編寫

Car car = new Car();
Customer customer = new Customer();
customer.setAge(65);
kieSession.insert(customer);
kieSession.insert(car);
kieSession.fireAllRules(new RuleNameStartsWithAgendaFilter("命名結(jié)果_"));

5.4 運行結(jié)果

用戶年齡>60歲，打0.9折
用戶有車，免費停車

也實現(xiàn)了需求

5.5 結(jié)論

通過when中使用 do[名字] 然后 then then 名字 也可以實現(xiàn)。

6、實現(xiàn) if else if 的效果

6.1 需求

完成類似 if else if else效果。見下方的各種執(zhí)行結(jié)果。

6.2 規(guī)則文件

rule "if else-if"
    when
       $customer: Customer(age > 60) // 規(guī)則內(nèi)存中存在Customer對象，并且age>60
        if($customer.getLevel() == 1) do[level1] // 用戶的級別是1，執(zhí)行then[level1],然后繼續(xù)執(zhí)行下方的條件
        else if ($customer.getLevel() == 2) break[level2] // 用戶的級別是2，執(zhí)行then[level2],不在執(zhí)行下方的條件
        else do[levelOther] // 其他的level級別，執(zhí)行then[levelOther],然后在執(zhí)行下方的條件
        Car()
    then
        System.out.println("我執(zhí)行了");
    then[level1]
        System.out.println("level1");
    then[level2]
        System.out.println("level2");
    then[levelOther]
        System.out.println("levelOther");
end

6.3 執(zhí)行結(jié)果圖

6.4 各種執(zhí)行結(jié)果-也就是上圖的解釋

1、Customer的age小于60。
輸出： 沒有輸出。
2、Customer的age大于60并且level=1，沒有Car。
輸出： level1
3、Customer的age大于60并且level=1，有Car。
輸出： level1 我執(zhí)行了
4、Customer的age大于60并且level=2，沒有Car。
輸出： level2
5、Customer的age大于60并且level=2，有Car。
輸出： level2
6、Customer的age大于60并且level=3，沒有Car。
輸出： levelOther
7、Customer的age大于60并且level=3，有Car。
輸出： levelOther 我執(zhí)行了

6.5 do和 break 有什么區(qū)別

do：執(zhí)行完之后，還會繼續(xù)判斷后面的執(zhí)行條件。 （即還會執(zhí)行后面的Car判斷，根據(jù)是否有Car獲取不同的結(jié)果）
break：執(zhí)行完之后，不會在判斷后面的執(zhí)行條件。（即忽略了后面的Car判斷，rule執(zhí)行完了）

關于“drools中then部分怎么寫”的內(nèi)容就介紹到這里了，感謝大家的閱讀。如果想了解更多行業(yè)相關的知識，可以關注億速云行業(yè)資訊頻道，小編每天都會為大家更新不同的知識點。