Win7_KMS_激活腳本

@echo off&setlocal EnableDelayedExpansion&color 5e
title KMS_Activation for Windows 7 - (Comlan)

echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo :: 自動(dòng)檢查 Win7 的版本，導(dǎo)入相應(yīng)的 KMS 密鑰 ::
echo :: ::
echo :: 然后連接指定的 KMS 服務(wù)器激活 Win7 ::
echo :: ::
echo :: 2017-10 ::
echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo.&echo.

:: 如果激活失敗，可能是因?yàn)檫B不到KMS服務(wù)器了，
:: 你僅需修改下面的KMS服務(wù)器地址

set KMS_Sev=172.19.34.146

::======================= 以下內(nèi)容無需更改 ======================
call :adminchk

set Professional=FJ82H-XT6CR-J8D7P-XQJJ2-GPDD4
set ProfessionalN=MRPKT-YTG23-K7D7T-X2JMM-QY7MG
set ProfessionalE=W82YF-2Q76Y-63HXB-FGJG9-GF7QX
set Enterprise=33PXH-7Y6KF-2VJC9-XBBR8-HVTHH
set EnterpriseN=YDRBP-3D83W-TY26F-D46B2-XCKRJ
set EnterpriseE=C29WB-22CC8-VJ326-GHFJW-H9DH4J

for /f "tokens=3 delims= " %%i in ('reg QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "EditionID"') do set EditionID=%%i

if defined %EditionID% (
cscript //Nologo %windir%\system32\slmgr.vbs /ipk !%EditionID%!
cscript //Nologo %windir%\system32\slmgr.vbs /skms %KMS_Sev%
cscript //Nologo %windir%\system32\slmgr.vbs /ato
) else (
echo.&echo Not found DEFINED Key: "%EditionID%".
echo.
)
pause
exit

:adminchk
reg query "HKU\S-1-5-19" >nul 2>nul || (
cls&echo.&echo Run as ADMINISTRATOR, Pls.
echo.&echo Press any key to exit.
echo.&pause>nul
exit)
goto :EOF