.bat腳本基本命令語法

目錄
批處理的常見命令（未列舉的命令還比較多，請查閱幫助信息）
     1、REM 和 ::
     2、ECHO 和 @
     3、PAUSE
     4、ERRORLEVEL
     5、TITLE
     6、COLOR
     7、mode 配置系統(tǒng)設(shè)備
     8、GOTO 和 :
     9、FIND
     10、START
     11、assoc 和 ftype
     12、pushd 和 popd
     13、CALL
     14、shift
     15、IF
     16、setlocal 與 變量延遲
     17、ATTRIB  顯示或更改文件屬性
======================================================
介紹命令
1、REM 和 ::
REM為注釋命令，一般用來給程序加上注解，該命令后的內(nèi)容不被執(zhí)行，但能回顯。
其次, :: 也可以起到rem 的注釋作用, 而且更簡潔有效; 但有兩點(diǎn)需要注意：
第一, 任何以冒號(hào):開頭的字符行, 在批處理中都被視作標(biāo)號(hào), 而直接忽略其后的所有內(nèi)容。
有效標(biāo)號(hào)：冒號(hào)后緊跟一個(gè)以字母數(shù)字開頭的字符串，goto語句可以識(shí)別。
無效標(biāo)號(hào)：冒號(hào)后緊跟一個(gè)非字母數(shù)字的一個(gè)特殊符號(hào)，goto無法識(shí)別的標(biāo)號(hào)，可以起到注釋作用，所以 :: 常被用作注釋符號(hào)，其實(shí) :+ 也可起注釋作用。
第 二, 與rem 不同的是, ::后的字符行在執(zhí)行時(shí)不會(huì)回顯, 無論是否用echo on打開命令行回顯狀態(tài), 因?yàn)槊罱忉屍鞑徽J(rèn)為他是一個(gè)有效的命令行, 就此點(diǎn)來看, rem 在某些場合下將比 :: 更為適用; 另外, rem 可以用于 config.sys 文件中。

行內(nèi)注釋格式：%注釋內(nèi)容%  （不常用，慎用）


2、ECHO 和 @
@字符放在命令前將關(guān)閉該命令回顯，無論此時(shí)echo是否為打開狀態(tài)。
echo命令的作用列舉如下：
（1）打開回顯或關(guān)閉回顯功能
    格式:echo [{ on|off }]
    如果想關(guān)閉“ECHO OFF”命令行自身的顯示，則需要在該命令行前加上“@”。
（2）顯示當(dāng)前ECHO設(shè)置狀態(tài)
    格式:echo
（3）輸出提示信息 
    格式：ECHO 信息內(nèi)容
    上述是ECHO命令常見的三種用法，也是大家熟悉和會(huì)用的，但作為DOS命令淘金者你還應(yīng)該知道下面的技巧：
（4）關(guān)閉DOS命令提示符 
    在DOS提示符狀態(tài)下鍵入ECHO OFF，能夠關(guān)閉DOS提示符的顯示使屏幕只留下光標(biāo)，直至鍵入ECHO ON，提示符才會(huì)重新出現(xiàn)。
（5）輸出空行，即相當(dāng)于輸入一個(gè)回車 
    格式：ECHO．
    值得注意的是命令行中的“．”要緊跟在ECHO后面中間不能有空格，否則“．”將被當(dāng)作提示信息輸出到屏幕。另外“．”可以用，：；”／[\]＋等任一符號(hào)替代。
    命令ECHO．輸出的回車，經(jīng)DOS管道轉(zhuǎn)向可以作為其它命令的輸入，比如echo.|time即相當(dāng)于在TIME命令執(zhí)行后給出一個(gè)回車。所以執(zhí)行時(shí)系統(tǒng)會(huì)在顯示當(dāng)前時(shí)間后，自動(dòng)返回到DOS提示符狀態(tài)
（6）答復(fù)命令中的提問 
    格式：ECHO 答復(fù)語|命令文件名
上述格式可以用于簡化一些需要人機(jī)對話的命令（如：CHKDSK／F；FORMAT Drive:；del *.*）的操作，它是通過DOS管道命令把ECHO命令輸出的預(yù)置答復(fù)語作為人機(jī)對話命令的輸入。下面的例子就相當(dāng)于在調(diào)用的命令出現(xiàn)人機(jī)對話時(shí)輸入“Y”回車：
C:>ECHO Y|CHKDSK/F
C:>ECHO Y|DEL A :*.*
（7）建立新文件或增加文件內(nèi)容 
格式：ECHO 文件內(nèi)容>文件名
      ECHO 文件內(nèi)容>>文件名
例如：
C:>ECHO @ECHO OFF>AUTOEXEC.BAT建立自動(dòng)批處理文件
C:>ECHO C:\CPAV\BOOTSAFE>>AUTOEXEC.BAT向自動(dòng)批處理文件中追加內(nèi)容
C:>TYPE AUTOEXEC.BAT顯示該自動(dòng)批處理文件
@ECHO OFF
C:\CPAV\BOOTSAFE
（8）向打印機(jī)輸出打印內(nèi)容或打印控制碼 
格式：ECHO 打印機(jī)控制碼>;PRN
      ECHO 打印內(nèi)容>;PRN
下面的例子是向M－1724打印機(jī)輸入打印控制碼。＜Alt＞156是按住Alt鍵在小鍵盤鍵入156，類似情況依此類推：
C:>ECHO +156+42+116>;PRN（輸入下劃線命令FS＊t）
C:>ECHO [email=+155@]+155@>;PRN[/email]（輸入初始化命令ESC@）
C:>ECHO.>;PRN（換行）
（9）使喇叭鳴響 
C:>ECHO ^G
“^G”是在dos窗口中用Ctrl＋G或Alt＋007輸入，輸入多個(gè)^G可以產(chǎn)生多聲鳴響。使用方法是直接將其加入批處理文件中或做成批處理文件調(diào)用。
這里的“^G”屬于特殊符號(hào)的使用，請看本文后面的章節(jié)


3、PAUSE
PAUSE，玩游戲的人都知道，暫停的意思
在這里就是停止系統(tǒng)命令的執(zhí)行并顯示下面的內(nèi)容。
例：
PAUSE
運(yùn)行顯示：
請按任意鍵繼續(xù). . .
要顯示其他提示語，可以這樣用：
Echo 其他提示語 & pause > nul


4、errorlevel
程序返回碼
echo %errorlevel%
每個(gè)命令運(yùn)行結(jié)束，可以用這個(gè)命令行格式查看返回碼
用于判斷剛才的命令是否執(zhí)行成功
默認(rèn)值為0，一般命令執(zhí)行出錯(cuò)會(huì)設(shè) errorlevel 為1


5、title
設(shè)置cmd窗口的標(biāo)題
title 新標(biāo)題        #可以看到cmd窗口的標(biāo)題欄變了


6、COLOR
設(shè)置默認(rèn)的控制臺(tái)前景和背景顏色。
COLOR [attr]
  attr        指定控制臺(tái)輸出的顏色屬性
顏色屬性由兩個(gè)十六進(jìn)制數(shù)字指定 -- 第一個(gè)為背景，第二個(gè)則為
前景。每個(gè)數(shù)字可以為以下任何值之一:
    0 = 黑色       8 = 灰色
    1 = 藍(lán)色       9 = 淡藍(lán)色
    2 = 綠色       A = 淡綠色
    3 = 湖藍(lán)色     B = 淡淺綠色
    4 = 紅色       C = 淡紅色
    5 = 紫色       D = 淡紫色
    6 = ×××       E = 淡×××
    7 = 白色       F = 亮白色
如果沒有給定任何參數(shù)，該命令會(huì)將顏色還原到 CMD.EXE 啟動(dòng)時(shí)
的顏色。這個(gè)值來自當(dāng)前控制臺(tái)窗口、/T 開關(guān)或
DefaultColor 注冊表值。
如果用相同的前景和背景顏色來執(zhí)行 COLOR 命令，COLOR 命令
會(huì)將 ERRORLEVEL 設(shè)置為 1。
例如: "COLOR fc" 在亮白色上產(chǎn)生亮紅色


7、mode 配置系統(tǒng)設(shè)備
配置系統(tǒng)設(shè)備。
串行口:　　　     MODE COMm[:] [BAUD=b] [PARITY=p] [DATA=d] [STOP=s]
                                [to=on|off] [xon=on|off] [odsr=on|off]
                                [octs=on|off] [dtr=on|off|hs]
                                [rts=on|off|hs|tg] [idsr=on|off]
設(shè)備狀態(tài):             MODE [device] [/STATUS]
打印重定向:　　 MODE LPTn[:]=COMm[:]
選定代碼頁:　　 MODE CON[:] CP SELECT=yyy
代碼頁狀態(tài):　　 MODE CON[:] CP [/STATUS]
顯示模式:　　     MODE CON[:] [COLS=c] [LINES=n]
擊鍵率:　             MODE CON[:] [RATE=r DELAY=d]
例：
mode con cols=113 lines=15 & color 9f
此命令設(shè)置DOS窗口大小：15行，113列


8、GOTO 和 :
GOTO會(huì)點(diǎn)編程的朋友就會(huì)知道這是跳轉(zhuǎn)的意思。
在批處理中允許以“:XXX”來構(gòu)建一個(gè)標(biāo)號(hào)，然后用GOTO XXX跳轉(zhuǎn)到標(biāo)號(hào):XXX處，然后執(zhí)行標(biāo)號(hào)后的命令。
例：
if {%1}=={} goto noparms
if "%2"=="" goto noparms
標(biāo)簽的名字可以隨便起，但是最好是有意義的字符串啦，前加個(gè)冒號(hào)用來表示這個(gè)字符串是標(biāo)簽，goto命令就是根據(jù)這個(gè)冒號(hào)（:）來尋找下一步跳到到那里。最好有一些說明這樣你別人看起來才會(huì)理解你的意圖啊。

例：
@echo off
:start
set /a var+=1
echo %var%
if %var% leq 3 GOTO start
pause
運(yùn)行顯示：
1
2
3
4

9、find
在文件中搜索字符串。
FIND [/V] [/C] [/N] [/I] [/OFF[LINE]] "string" [[drive:][path]filename[ ...]]
   /V        顯示所有未包含指定字符串的行。
   /C        僅顯示包含字符串的行數(shù)。
   /N        顯示行號(hào)。
   /I        搜索字符串時(shí)忽略大小寫。
   /OFF[LINE] 不要跳過具有脫機(jī)屬性集的文件。
   "string"   指定要搜索的文字串，
   [drive:][path]filename
         指定要搜索的文件。
如果沒有指定路徑，F(xiàn)IND 將搜索鍵入的或者由另一命令產(chǎn)生的文字。
Find常和type命令結(jié)合使用
Type [drive:][path]filename | find "string" [>tmpfile] #挑選包含string的行
Type [drive:][path]filename | find /v "string" #剔除文件中包含string的行
Type [drive:][path]filename | find /c #顯示文件行數(shù) 
以上用法將去除find命令自帶的提示語（文件名提示）

例：
@echo off
echo 111 >test.txt
echo 222 >>test.txt
find "111" test.txt
del test.txt
pause
運(yùn)行顯示如下：
---------- TEST.TXT
111
請按任意鍵繼續(xù). . .

例：
@echo off
echo 111 >test.txt
echo 222 >>test.txt
type test.txt|find "111" 
del test.txt
pause
運(yùn)行顯示如下：
111
請按任意鍵繼續(xù). . .

10、start 命令
批處理中調(diào)用外部程序的命令（該外部程序在新窗口中運(yùn)行，批處理程序繼續(xù)往下執(zhí)行，不理會(huì)外部程序的運(yùn)行狀況），如果直接運(yùn)行外部程序則必須等外部程序完成后才繼續(xù)執(zhí)行剩下的指令
例：start explorer d:\
調(diào)用圖形界面打開D盤


11、assoc 和 ftype
文件關(guān)聯(lián)
assoc 設(shè)置'文件擴(kuò)展名'關(guān)聯(lián)，關(guān)聯(lián)到'文件類型'
ftype 設(shè)置'文件類型'關(guān)聯(lián)，關(guān)聯(lián)到'執(zhí)行程序和參數(shù)'
當(dāng)你雙擊一個(gè).txt文件時(shí)，windows并不是根據(jù).txt直接判斷用 notepad.exe 打開
而是先判斷.txt屬于 txtfile '文件類型'
再調(diào)用 txtfile 關(guān)聯(lián)的命令行 txtfile=%SystemRoot%\system32\NOTEPAD.EXE %1
可以在"文件夾選項(xiàng)"→"文件類型"里修改這2種關(guān)聯(lián)
assoc           #顯示所有'文件擴(kuò)展名'關(guān)聯(lián)
assoc .txt      #顯示.txt代表的'文件類型'，結(jié)果顯示 .txt=txtfile
assoc .doc      #顯示.doc代表的'文件類型'，結(jié)果顯示 .doc=Word.Document.8
assoc .exe      #顯示.exe代表的'文件類型'，結(jié)果顯示 .exe=exefile
ftype           #顯示所有'文件類型'關(guān)聯(lián)
ftype exefile   #顯示exefile類型關(guān)聯(lián)的命令行，結(jié)果顯示 exefile="%1" %* 
assoc .txt=Word.Document.8
設(shè)置.txt為word類型的文檔，可以看到.txt文件的圖標(biāo)都變了
assoc .txt=txtfile
恢復(fù).txt的正確關(guān)聯(lián)

ftype exefile="%1" %*
恢復(fù) exefile 的正確關(guān)聯(lián)
如果該關(guān)聯(lián)已經(jīng)被破壞，可以運(yùn)行 command.com ，再輸入這條命令


12、pushd 和 popd
切換當(dāng)前目錄
@echo off
c: & cd\ & md mp3       #在 C:\ 建立 mp3 文件夾
md d:\mp4               #在 D:\ 建立 mp4 文件夾
cd /d d:\mp4            #更改當(dāng)前目錄為 d:\mp4
pushd c:\mp3            #保存當(dāng)前目錄，并切換當(dāng)前目錄為 c:\mp3
popd                    #恢復(fù)當(dāng)前目錄為剛才保存的 d:\mp4
一般用處不大，在當(dāng)前目錄名不確定時(shí)，會(huì)有點(diǎn)幫助。（dos編程中很有用）


13、CALL
CALL命令可以在批處理執(zhí)行過程中調(diào)用另一個(gè)批處理，當(dāng)另一個(gè)批處理執(zhí)行完后，再繼續(xù)執(zhí)行原來的批處理
CALL command
調(diào)用一條批處理命令，和直接執(zhí)行命令效果一樣，特殊情況下很有用，比如變量的多級(jí)嵌套，見教程后面。在批處理編程中，可以根據(jù)一定條件生成命令字符串，用call可以執(zhí)行該字符串，見例子。
CALL [drive:][path]filename [batch-parameters]
調(diào)用的其它批處理程序。filename 參數(shù)必須具有 .bat 或 .cmd 擴(kuò)展名。
CALL :label arguments
調(diào)用本文件內(nèi)命令段，相當(dāng)于子程序。被調(diào)用的命令段以標(biāo)簽:label開頭
以命令goto :eof結(jié)尾。
另外，批腳本文本參數(shù)參照(%0、%1、等等)已如下改變:
     批腳本里的 %* 指出所有的參數(shù)(如 %1 %2 %3 %4 %5 ...)
     批參數(shù)(%n)的替代已被增強(qiáng)。您可以使用以下語法:（看不明白的直接運(yùn)行后面的例子）
         %~1         - 刪除引號(hào)(")，擴(kuò)充 %1
         %~f1        - 將 %1 擴(kuò)充到一個(gè)完全合格的路徑名
         %~d1        - 僅將 %1 擴(kuò)充到一個(gè)驅(qū)動(dòng)器號(hào)
         %~p1        - 僅將 %1 擴(kuò)充到一個(gè)路徑
         %~n1        - 僅將 %1 擴(kuò)充到一個(gè)文件名
         %~x1        - 僅將 %1 擴(kuò)充到一個(gè)文件擴(kuò)展名
         %~s1        - 擴(kuò)充的路徑指含有短名
         %~a1        - 將 %1 擴(kuò)充到文件屬性
         %~t1        - 將 %1 擴(kuò)充到文件的日期/時(shí)間
         %~z1        - 將 %1 擴(kuò)充到文件的大小
         %~$PATH : 1 - 查找列在 PATH 環(huán)境變量的目錄，并將 %1
                       擴(kuò)充到找到的第一個(gè)完全合格的名稱。如果環(huán)境
                       變量名未被定義，或者沒有找到文件，此組合鍵會(huì)
                       擴(kuò)充到空字符串
    可以組合修定符來取得多重結(jié)果:
        %~dp1       - 只將 %1 擴(kuò)展到驅(qū)動(dòng)器號(hào)和路徑
        %~nx1       - 只將 %1 擴(kuò)展到文件名和擴(kuò)展名
        %~dp$PATH:1 - 在列在 PATH 環(huán)境變量中的目錄里查找 %1，
                       并擴(kuò)展到找到的第一個(gè)文件的驅(qū)動(dòng)器號(hào)和路徑。
        %~ftza1     - 將 %1 擴(kuò)展到類似 DIR 的輸出行。
    在上面的例子中，%1 和 PATH 可以被其他有效數(shù)值替換。
%~ 語法被一個(gè)有效參數(shù)號(hào)碼終止。%~ 修定符不能跟 %*使用
注意：參數(shù)擴(kuò)充時(shí)不理會(huì)參數(shù)所代表的文件是否真實(shí)存在，均以當(dāng)前目錄進(jìn)行擴(kuò)展
要理解上面的知識(shí)，下面的例子很關(guān)鍵。
例：
@echo off
Echo 產(chǎn)生一個(gè)臨時(shí)文件 > tmp.txt
Rem 下行先保存當(dāng)前目錄，再將c:\windows設(shè)為當(dāng)前目錄
pushd c:\windows
Call :sub tmp.txt
Rem 下行恢復(fù)前次的當(dāng)前目錄
Popd
Call :sub tmp.txt
pause
Del tmp.txt
exit
:sub
Echo 刪除引號(hào)： %~1
Echo 擴(kuò)充到路徑： %~f1
Echo 擴(kuò)充到一個(gè)驅(qū)動(dòng)器號(hào)： %~d1
Echo 擴(kuò)充到一個(gè)路徑： %~p1 
Echo 擴(kuò)充到一個(gè)文件名： %~n1
Echo 擴(kuò)充到一個(gè)文件擴(kuò)展名： %~x1
Echo 擴(kuò)充的路徑指含有短名： %~s1 
Echo 擴(kuò)充到文件屬性： %~a1 
Echo 擴(kuò)充到文件的日期/時(shí)間： %~t1 
Echo 擴(kuò)充到文件的大?。?%~z1 
Echo 擴(kuò)展到驅(qū)動(dòng)器號(hào)和路徑：%~dp1
Echo 擴(kuò)展到文件名和擴(kuò)展名：%~nx1
Echo 擴(kuò)展到類似 DIR 的輸出行：%~ftza1
Echo.
Goto :eof
例：
set aa=123456
set cmdstr=echo %aa%
call %cmdstr%
pause
本例中如果不用call，而直接運(yùn)行%cmdstr%，將顯示結(jié)果%aa%，而不是123456

14、shift
更改批處理文件中可替換參數(shù)的位置。
SHIFT [/n]
如果命令擴(kuò)展名被啟用，SHIFT 命令支持/n 命令行開關(guān)；該命令行開關(guān)告訴
命令從第 n 個(gè)參數(shù)開始移位；n 介于零和八之間。例如:
    SHIFT /2
會(huì)將 %3 移位到 %2，將 %4 移位到 %3，等等；并且不影響 %0 和 %1。
15、IF
IF 條件判斷語句，語法格式如下：
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
下面逐一介紹，更詳細(xì)的分析請看后面章節(jié)。

(1) IF [NOT] ERRORLEVEL number command
IF ERRORLEVEL這個(gè)句子必須放在某一個(gè)命令的后面，執(zhí)行命令后由IF ERRORLEVEL 來判斷命令的返回值。
Number的數(shù)字取值范圍0~255，判斷時(shí)值的排列順序應(yīng)該由大到小。返回的值大于等于指定的值時(shí)，條件成立
例：
@echo off
dir c:
rem退出代碼為>=1就跳至標(biāo)題1處執(zhí)行，>=0就跳至標(biāo)題0處執(zhí)行
IF ERRORLEVEL 1 goto 1
IF ERRORLEVEL 0 goto 0
Rem 上面的兩行不可交換位置，否則失敗了也顯示成功。
:0
echo 命令執(zhí)行成功！
Rem 程序執(zhí)行完畢跳至標(biāo)題exit處退出
goto exit
:1
echo 命令執(zhí)行失?。?br/>Rem 程序執(zhí)行完畢跳至標(biāo)題exit處退出
goto exit
:exit
pause
運(yùn)行顯示：命令執(zhí)行成功！
(2) IF [NOT] string1==string2 command
string1和string2都為字符的數(shù)據(jù)，英文內(nèi)字符的大小寫將看作不同，這個(gè)條件中的等于號(hào)必須是兩個(gè)（絕對相等的意思）
條件相等后即執(zhí)行后面的command
檢測當(dāng)前變量的值做出判斷，為了防止字符串中含有空格，可用以下格式
if [NOT] {string1}=={string2} command
if [NOT] [string1]==[string2] command
if [NOT] "string1"=="string2" command
這種寫法實(shí)際上將括號(hào)或引號(hào)當(dāng)成字符串的一部分了，只要等號(hào)左右兩邊一致就行了，比如下面的寫法就不行：
if {string1}==[string2] command

(3) IF [NOT] EXIST filename command
EXIST filename為文件或目錄存在的意思
echo off
IF EXIST autoexec.bat echo 文件存在！
IF not EXIST autoexec.bat echo 文件不存在！
這個(gè)批處理大家可以放在C盤和D盤分別執(zhí)行，看看效果



16、setlocal 與 變量延遲
本條內(nèi)容引用[英雄出品]的批處理教程：
要想進(jìn)階，變量延遲是必過的一關(guān)！所以這一部分希望你能認(rèn)真看。
為了更好的說明問題，我們先引入一個(gè)例子。
例1:
@echo off
set a=4
set a=5 & echo %a%
pause
結(jié)果：4
解說：為什么是4而不是5呢？在echo之前明明已經(jīng)把變量a的值改成5了？
讓我們先了解一下批處理運(yùn)行命令的機(jī)制：
批 處理讀取命令時(shí)是按行讀取的（另外例如for命令等，其后用一對圓括號(hào)閉合的所有語句也當(dāng)作一行），在處理之前要完成必要的預(yù)處理工作，這其中就包括對該 行命令中的變量賦值。我們現(xiàn)在分析一下例1，批處理在運(yùn)行到這句“set a=5 & echo %a%”之前，先把這一句整句讀取并做了預(yù)處理——對變量a賦了值，那么%a%當(dāng)然就是4了！（沒有為什么，批處理就是這樣做的。）
而為了能夠感知環(huán)境變量的動(dòng)態(tài)變化，批處理設(shè)計(jì)了變量延遲。簡單來說，在讀取了一條完整的語句之后，不立即對該行的變量賦值，而會(huì)在某個(gè)單條語句執(zhí)行之前再進(jìn)行賦值，也就是說“延遲”了對變量的賦值。
那么如何開啟變量延遲呢？變量延遲又需要注意什么呢？舉個(gè)例子說明一下：
例2:
@echo off
setlocal enabledelayedexpansion
set a=4
set a=5 & echo !a!
pause 
結(jié)果：5
解說：啟動(dòng)了變量延遲，得到了正確答案。變量延遲的啟動(dòng)語句是“setlocal enabledelayedexpansion”，并且變量要用一對嘆號(hào)“!!”括起來（注意要用英文的嘆號(hào)），否則就沒有變量延遲的效果。
分析一下例2，首先“setlocal enabledelayedexpansion”開啟變量延遲，然后“set a=4”先給變量a賦值為
4，“set a=5 & echo !a!”這句是給變量a賦值為5并輸出（由于啟動(dòng)了變量延遲，所以批處理能夠感知到動(dòng)態(tài)變化，即不是先給該行變量賦值，而是在運(yùn)行過程中給變量賦值，因此此時(shí)a的值就是5了）。
再舉一個(gè)例子鞏固一下。
例3:
@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,5) do (
set a=%%i
echo !a!
)
pause
結(jié)果：
1
2
3
4
5
解說：本例開啟了變量延遲并用“!!”將變量擴(kuò)起來，因此得到我們預(yù)期的結(jié)果。如果不用變量延遲會(huì)出現(xiàn)什
么結(jié)果呢？結(jié)果是這樣的：
ECHO 處于關(guān)閉狀態(tài)。
ECHO 處于關(guān)閉狀態(tài)。
ECHO 處于關(guān)閉狀態(tài)。
ECHO 處于關(guān)閉狀態(tài)。
ECHO 處于關(guān)閉狀態(tài)。
即沒有感知到for語句中的動(dòng)態(tài)變化。
提示：在沒有開啟變量延遲的情況下，某條命令行中的變量改變，必須到下一條命令才能體現(xiàn)。這一點(diǎn)也可以加以利用，看例子。
例：交換兩個(gè)變量的值，且不用中間變量
@echo off
::目的：交換兩個(gè)變量的值，但是不使用臨時(shí)變量
::Code by JM 2007-1-24 [email=CMD@XP]CMD@XP[/email]
::出處：http://www.cn-dos.net/forum/viewthread.php?tid=27078
set var1=abc
set var2=123
echo 交換前： var1=%var1% var2=%var2%
set var1=%var2%& set var2=%var1%
echo 交換后： var1=%var1% var2=%var2%
pause

17、ATTRIB  顯示或更改文件屬性
ATTRIB [+R|-R] [+A|-A] [+S|-S] [+H|-H] [[drive:] [path] filename] [/S [/D]]
  +   設(shè)置屬性。
  -    清除屬性。
  R   只讀文件屬性。
  A   存檔文件屬性。
  S   系統(tǒng)文件屬性。
  H   隱藏文件屬性。
  [drive:][path][filename]
      指定要處理的文件屬性。
  /S  處理當(dāng)前文件夾及其子文件夾中的匹配文件。
  /D  也處理文件夾。

例：
md autorun
attrib +a +s +h autorun
上面的命令將建立文件夾autorun，然后將其設(shè)為存檔、系統(tǒng)、隱藏屬性

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
第二節(jié) 常用特殊符號(hào)
    1、@  命令行回顯屏蔽符
    2、%  批處理變量引導(dǎo)符
    3、>   重定向符
    4、>>  重定向符
    5、<、>&、<& 重定向符
    6、|  命令管道符
    7、^  轉(zhuǎn)義字符
    8、&  組合命令
    9、&& 組合命令
    10、||  組合命令
    11、""  字符串界定符
    12、, 逗號(hào)
    13、; 分號(hào)
    14、() 括號(hào)
    15、! 感嘆號(hào)
    16、批處理中可能會(huì)見到的其它特殊標(biāo)記符: （略）
        CR(0D) 命令行結(jié)束符 
        Escape(1B) ANSI轉(zhuǎn)義字符引導(dǎo)符 
        Space(20) 常用的參數(shù)界定符 
        Tab(09) ; = 不常用的參數(shù)界定符 
        + COPY命令文件連接符 
        * ? 文件通配符 
        / 參數(shù)開關(guān)引導(dǎo)符 
        : 批處理標(biāo)簽引導(dǎo)符 

廢話少說，開講了
1、@  命令行回顯屏蔽符
這個(gè)字符在批處理中的意思是關(guān)閉當(dāng)前行的回顯。我們從前幾課知道
ECHO OFF可以關(guān)閉掉整個(gè)批處理命令的回顯，但不能關(guān)掉ECHO OFF這個(gè)命令，現(xiàn)在我們在ECHO OFF這個(gè)命令前加個(gè)@，就可以達(dá)到所有命令均不回顯的要求

2、%  批處理變量引導(dǎo)符
這個(gè)百分號(hào)嚴(yán)格來說是算不上命令的，它只是批處理中的參數(shù)而已（多個(gè)%一起使用的情況除外，以后還將詳細(xì)介紹）。
引用變量用%var%，調(diào)用程序外部參數(shù)用%1至%9等等
%0  %1  %2  %3  %4  %5  %6  %7  %8  %9  %*為命令行傳遞給批處理的參數(shù)
%0 批處理文件本身，包括完整的路徑和擴(kuò)展名
%1 第一個(gè)參數(shù)
%9 第九個(gè)參數(shù)
%* 從第一個(gè)參數(shù)開始的所有參數(shù)
參數(shù)%0具有特殊的功能，可以調(diào)用批處理自身，以達(dá)到批處理本身循環(huán)的目的，也可以復(fù)制文件自身等等。
例：最簡單的復(fù)制文件自身的方法
copy %0 d:\wind.bat
小技巧：添加行內(nèi)注釋
%注釋內(nèi)容%（可以用作行內(nèi)注釋，不能出現(xiàn)重定向符號(hào)和管道符號(hào)）
為什么這樣呢？此時(shí)“注釋內(nèi)容”其實(shí)被當(dāng)作變量，其值是空的，故只起注釋作用，不過這種用法容易出現(xiàn)語法錯(cuò)誤，一般不用。

3、>   重定向符
輸出重定向命令
DOS的標(biāo)準(zhǔn)輸入輸出通常是在標(biāo)準(zhǔn)設(shè)備鍵盤和顯示器上進(jìn)行的，利用重定向,可以方便地將輸入輸出改向磁盤文件或其它設(shè)備。其中: 
1.大于號(hào)“>”將命令發(fā)送到文件或設(shè)備，例如打印機(jī)>prn。使用大于號(hào)“>”時(shí)，有些命令輸出(例如錯(cuò)誤消息)不能重定向。
2.雙大于號(hào)“>>”將命令輸出添加到文件結(jié)尾而不刪除文件中已有的信息。
3.小于號(hào)“<”從文件而不是鍵盤上獲取命令所需的輸入。
4.>&符號(hào)將輸出從一個(gè)默認(rèn)I/O流(stdout,stdin,stderr)重新定向到另一個(gè)默認(rèn)I/O流。
例如，command >output_file 2>&1將處理command過程中的所有錯(cuò)誤信息從屏幕重定向到標(biāo)準(zhǔn)文件輸出中。標(biāo)準(zhǔn)輸出的數(shù)值如下所示：
命令重定向的標(biāo)準(zhǔn)句柄

這個(gè)字符的意思是傳遞并且覆蓋，他所起的作用是將運(yùn)行的結(jié)果傳遞到后面的范圍（后邊可以是文件，也可以是默認(rèn)的系統(tǒng)控制臺(tái)）
在NT系列命令行中，重定向的作用范圍由整個(gè)命令行轉(zhuǎn)變?yōu)閱蝹€(gè)命令語句，受到了命令分隔符&,&&,||和語句塊的制約限制。
比如：
使用命令：echo hello >1.txt將建立文件1.txt，內(nèi)容為”hello “（注意行尾有一空格）
使用命令：echo hello>1.txt將建立文件1.txt，內(nèi)容為”hello“（注意行尾沒有空格）：
具體重定向?qū)嵗埧次业牧硗庖黄恼拢篋OS的重定向命令及在安全方面的應(yīng)用

4、>>  重定向符
輸出重定向命令
這個(gè)符號(hào)的作用和>有點(diǎn)類似，但他們的區(qū)別是>>是傳遞并在文件的末尾追加，而>是覆蓋
用法同上
同樣拿1.txt做例子
使用命令：
echo hello > 1.txt
echo world >>1.txt
這時(shí)候1.txt 內(nèi)容如下:
hello
world

5、<、>&、<& 重定向符
這三個(gè)命令也是管道命令，但它們一般不常用，你只需要知道一下就ok了，當(dāng)然如果想仔細(xì)研究的話，可以自己查一下資料。(本人已查過，網(wǎng)上也查不到相關(guān)資料)
<，輸入重定向命令，從文件中讀入命令輸入，而不是從鍵盤中讀入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
這樣就可以不等待輸入直接修改當(dāng)前日期
>&，將一個(gè)句柄的輸出寫入到另一個(gè)句柄的輸入中。
<&，剛好和>&相反，從一個(gè)句柄讀取輸入并將其寫入到另一個(gè)句柄輸出中。
常用句柄：0、1、2，未定義句柄：3—9
1>nul 表示禁止輸出正確的信息
2>nul 表示禁止輸出錯(cuò)誤信息。
其中的1與2都是代表某個(gè)數(shù)據(jù)流輸入輸出的地址（NT CMD 稱之為句柄，MSDOS稱之為設(shè)備）。
句柄0：標(biāo)準(zhǔn)輸入stdin，鍵盤輸入
句柄1：標(biāo)準(zhǔn)輸出stdout，輸出到命令提示符窗口（console，代碼為CON）
句柄2：標(biāo)準(zhǔn)錯(cuò)誤stderr，輸出到命令提示符窗口（console，代碼為CON）
其中的stdin可被<重定向，stdout可被>、>>重定向。
我們已經(jīng)知道讀取文本中的內(nèi)容可以用for命令，但如果只需要讀取第一行用for命令就有點(diǎn)麻煩。簡單的辦法如下:
@echo off
set /p str=<%0
echo %str%
pause
運(yùn)行顯示批處理文件自身的第一行：@echo off

6、|  命令管道符
格式：第一條命令 | 第二條命令 [| 第三條命令...]
將第一條命令的結(jié)果作為第二條命令的參數(shù)來使用，記得在unix中這種方式很常見。
例如：
dir c:\|find "txt"
以上命令是：查找C：\所有，并發(fā)現(xiàn)TXT字符串。
FIND的功能請用 FIND /? 自行查看
在不使format的自動(dòng)格式化參數(shù)時(shí)，我是這樣來自動(dòng)格式化A盤的
echo y|format a: /s /q /v:system
用過format的都知道，再格盤時(shí)要輸入y來確認(rèn)是否格盤，這個(gè)命令前加上echo y并用|字符來將echo y的結(jié)果傳給format命令
從而達(dá)到自動(dòng)輸入y的目的
（這條命令有危害性，測試時(shí)請慎重）


7、^  轉(zhuǎn)義字符
^是對特殊符號(hào)<,>,&的前導(dǎo)字符，在命令中他將以上3個(gè)符號(hào)的特殊功能去掉，僅僅只把他們當(dāng)成符號(hào)而不使用他們的特殊意義。
比如
echo test ^>1.txt
結(jié)果則是：test > 1.txt
他沒有追加在1.txt里，呵呵。只是顯示了出來
另外，此轉(zhuǎn)義字符還可以用作續(xù)行符號(hào)。
舉個(gè)簡單的例子：
@echo off
echo 英雄^
是^
好^
男人
pause
不用多說，自己試一下就明白了。
為什么轉(zhuǎn)義字符放在行尾可以起到續(xù)行符的作用呢？原因很簡單，因?yàn)槊啃心┪策€有一個(gè)看不見的符號(hào)，即回車符，轉(zhuǎn)義字符位于行尾時(shí)就讓回車符失效了，從而起到了續(xù)行的作用。


8、& 組合命令
語法：第一條命令 & 第二條命令 [& 第三條命令...]
&、&&、||為組合命令，顧名思義，就是可以把多個(gè)命令組合起來當(dāng)一個(gè)命令來執(zhí)行。這在批處理腳本里是允許的，而且用的非常廣泛。因?yàn)榕幚碚J(rèn)行不認(rèn)命令數(shù)目。
這個(gè)符號(hào)允許在一行中使用2個(gè)以上不同的命令，當(dāng)?shù)谝粋€(gè)命令執(zhí)行失敗了，也不影響后邊的命令執(zhí)行。
這里&兩邊的命令是順序執(zhí)行的，從前往后執(zhí)行。
比如：
dir z:\ & dir y:\ & dir c:\
以上命令會(huì)連續(xù)顯示z,y,c盤的內(nèi)容，不理會(huì)該盤是否存在


9、&& 組合命令
語法：第一條命令 && 第二條命令 [&& 第三條命令...]
用這種方法可以同時(shí)執(zhí)行多條命令，當(dāng)碰到執(zhí)行出錯(cuò)的命令后將不執(zhí)行后面的命令，如果一直沒有出錯(cuò)則一直執(zhí)行完所有命令
這個(gè)命令和上邊的類似，但區(qū)別是，第一個(gè)命令失敗時(shí)，后邊的命令也不會(huì)執(zhí)行
dir z:\ && dir y:\ && dir c:\


10、||  組合命令
語法：第一條命令 || 第二條命令 [|| 第三條命令...]
用這種方法可以同時(shí)執(zhí)行多條命令，當(dāng)一條命令失敗后才執(zhí)行第二條命令，當(dāng)碰到執(zhí)行正確的命令后將不執(zhí)行后面的命令，如果沒有出現(xiàn)正確的命令則一直執(zhí)行完所有命令；

提示：組合命令和重定向命令一起使用必須注意優(yōu)先級(jí)
管道命令的優(yōu)先級(jí)高于重定向命令，重定向命令的優(yōu)先級(jí)高于組合命令
問題：把C盤和D盤的文件和文件夾列出到a.txt文件中?？蠢?br/>dir c:\ && dir d:\ > a.txt
這 樣執(zhí)行后a.txt里只有D盤的信息！為什么？因?yàn)榻M合命令的優(yōu)先級(jí)沒有重定向命令的優(yōu)先級(jí)高！所以這句在執(zhí)行時(shí)將本行分成這兩部分：dir c:\和dir d:\ > a.txt，而并不是如你想的這兩部分：dir c:\ && dir d:\和> a.txt。要使用組合命令&&達(dá)到題目的要求，必須得這么寫：
dir c:\ > a.txt && dir d:\ >> a.txt
這樣，依據(jù)優(yōu)先級(jí)高低，DOS將把這句話分成以下兩部分：dir c:\ > a.txt和dir d:\ >> a.txt。例十八中的幾句的差別比較特殊，值得好好研究體會(huì)一下。
當(dāng)然這里還可以利用&命令（自己想一下道理哦）：
dir c:\ > a.txt & dir d:\ >> a.txt
[這個(gè)也可以用 dir c:\;d:\ >>a.txt 來實(shí)現(xiàn)]

11、""  字符串界定符
雙引號(hào)允許在字符串中包含空格，進(jìn)入一個(gè)特殊目錄可以用如下方法
cd "program files"
cd progra~1
cd pro*
以上三種方法都可以進(jìn)入program files這個(gè)目錄


12、, 逗號(hào)
逗號(hào)相當(dāng)于空格，在某些情況下“,”可以用來當(dāng)做空格使
比如
dir,c:\

13、; 分號(hào)
分號(hào)，當(dāng)命令相同時(shí)，可以將不同目標(biāo)用；來隔離，但執(zhí)行效果不變，如執(zhí)行過程中發(fā)生錯(cuò)誤，則只返回錯(cuò)誤報(bào)告，但程序仍會(huì)執(zhí)行。（有人說不會(huì)繼續(xù)執(zhí)行，其實(shí)測試一下就知道了，只不過它的執(zhí)行有個(gè)規(guī)則，請看下面的規(guī)則）
比如：
dir c:\;d:\;e:\;z:\
以上命令相當(dāng)于
dir c:\
dir d:\
dir e:\
dir f:\
如果其中z盤不存在，運(yùn)行顯示：系統(tǒng)找不到指定的路徑。然后終止命令的執(zhí)行。
例：dir c:\;d:\;e:\1.txt
以上命令相當(dāng)于
dir c:\
dir d:\
dir e:\1.txt
其中文件e:\1.txt不存在，但e盤存在，有錯(cuò)誤提示，但命令仍會(huì)執(zhí)行。

規(guī)則：(我是在操作系統(tǒng)是XP SP3,英文版下測試的)
1.如果目標(biāo)路徑不存在，則整個(gè)語句都不執(zhí)行，例如dir c:\;c:\dfdfdf\a.txt，則根本不會(huì)執(zhí)行，因?yàn)槲覜]有c:\dfdfdf\這個(gè)目錄；
2.如果路徑存在，僅文件不存在，則會(huì)繼續(xù)執(zhí)行，并且提示文件不存在的錯(cuò)誤，例如：dir c:\;c:\temp\a.txt，我的目錄中有c:\temp\文件夾，但這個(gè)目錄下面沒有1.txt這個(gè)文件。
就說這些了!各位有什么意見請回貼!有什么疑問請到BAT交流區(qū)發(fā)貼!下一節(jié)改進(jìn)!


14、() 括號(hào)
小括號(hào)在批處理編程中有特殊的作用，左右括號(hào)必須成對使用，括號(hào)中可以包括多行命令，這些命令將被看成一個(gè)整體，視為一條命令行。
    括號(hào)在for語句和if語句中常見，用來嵌套使用循環(huán)或條件語句，其實(shí)括號(hào)()也可以單獨(dú)使用，請看例子。
例：
命令：echo 1 & echo 2 & echo 3
可以寫成：
(
echo 1
echo 2
echo 3
)
上面兩種寫法效果一樣，這兩種寫法都被視為是一條命令行。
注意：這種多條命令被視為一條命令行時(shí)，如果其中有變量，就涉及到變量延遲的問題。


15、! 感嘆號(hào)
沒啥說的，在變量延遲問題中，用來表示變量，即%var%應(yīng)該表示為!var!，請看前面的setlocal命令介紹。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
第二章 DOS循環(huán)：for命令詳解

講FOR之前呢,咋先告訴各位新手朋友,如果你有什么命令不懂,直接在CMD下面輸入:
name /? 這樣的格式來看系統(tǒng)給出的幫助文件,比如for /? 就會(huì)把FOR命令的幫助全部顯示出來!當(dāng)然許多菜鳥都看不懂....所以才會(huì)有那么多批處理文章!!!!俺也照顧菜鳥,把FOR命令用我自己的方式說明下!
正式開始:

一、基本格式
FOR %%variable IN (set) DO command [command-parameters]
  %%variable  指定一個(gè)單一字母表示可替換的參數(shù)。
  (set)      指定一個(gè)或一組文件?？梢允褂猛ㄅ浞?。
  command    指定對每個(gè)文件執(zhí)行的命令。
  command-parameters
             為特定命令指定參數(shù)或命令行開關(guān)。



參數(shù):FOR有4個(gè)參數(shù) /d   /l   /r   /f   他們的作用我在下面用例子解釋
現(xiàn)在開始講每個(gè)參數(shù)的意思

二、參數(shù) /d
FOR /D %%variable IN (set) DO command [command-parameters]
    如果集中包含通配符，則指定與目錄名匹配，而不與文件
    名匹配。
如果 Set (也就是我上面寫的 "相關(guān)文件或命令") 包含通配符（* 和 ?），將對與 Set 相匹配的每個(gè)目錄（而不是指定目錄中的文件組）執(zhí)行指定的 Command。
這個(gè)參數(shù)主要用于目錄搜索,不會(huì)搜索文件,看這樣的例子
@echo off
for /d %%i in (c:\*) do echo %%i
pause
運(yùn)行會(huì)把C盤根目錄下的全部目錄名字打印出來,而文件名字一個(gè)也不顯示!
在來一個(gè),比如我們要把當(dāng)前路徑下文件夾的名字只有1-3個(gè)字母的打出來
@echo off
for /d %%i in (???) do echo %%i
pause
這樣的話如果你當(dāng)前目錄下有目錄名字只有1-3個(gè)字母的,就會(huì)顯示出來,沒有就不顯示了
這里解釋下*號(hào)和?號(hào)的作用,*號(hào)表示任意N個(gè)字符,而?號(hào)只表示任意一個(gè)字符
知道作用了,給大家個(gè)思考題目!
@echo off
for /d %%i in (window?) do echo %%i
pause
保存到C盤下執(zhí)行,會(huì)顯示什么呢?自己看吧! 顯示：windows
/D參數(shù)只能顯示當(dāng)前目錄下的目錄名字,這個(gè)大家要注意!


三、參數(shù) /R
FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]
    檢查以 [drive:]path 為根的目錄樹，指向每個(gè)目錄中的
    FOR 語句。如果在 /R 后沒有指定目錄，則使用當(dāng)前
目錄。如果集僅為一個(gè)單點(diǎn)(.)字符，則枚舉該目錄樹。

遞歸
上面我們知道,/D只能顯示當(dāng)前路徑下的目錄名字,那么現(xiàn)在這個(gè)/R也是和目錄有關(guān),他能干嘛呢?放心他比/D強(qiáng)大多了!
他可以把當(dāng)前或者你指定路徑下的文件名字全部讀取,注意是文件名字,有什么用看例子!
請注意2點(diǎn)：
    1、set中的文件名如果含有通配符(？或*)，則列舉/R參數(shù)指定的目錄及其下面的所用子目錄中與set相符合的所有文件，無相符文件的目錄則不列舉。
    2、相反，如果set中為具體文件名，不含通配符，則枚舉該目錄樹（即列舉該目錄及其下面的所有子目錄），而不管set中的指定文件是否存在。這與前面所說的單點(diǎn)（.）枚舉目錄樹是一個(gè)道理，單點(diǎn)代表當(dāng)前目錄，也可視為一個(gè)文件。
例：
@echo off
for /r c:\ %%i in (*.exe) do echo %%i
pause
咱們把這個(gè)BAT保存到D盤隨便哪里然后執(zhí)行,我會(huì)就會(huì)看到,他把C盤根目錄,和每個(gè)目錄的子目錄下面全部的EXE文件都列出來了!!!!
例：
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
參數(shù)不一樣了吧!這個(gè)命令前面沒加那個(gè)C:\也就是搜索路徑,這樣他就會(huì)以當(dāng)前目錄為搜索路徑,比如你這個(gè)BAT你把他放在d:\test目錄下執(zhí)行,那么他就會(huì)把D:\test目錄和他下面的子目錄的全部EXE文件列出來!!!
例：
@echo off
for /r c:\ %%i in (boot.ini) do echo %%i
pause
運(yùn)行本例發(fā)現(xiàn)枚舉了c盤所有目錄，為了只列舉boot.ini存在的目錄，可改成下面這樣：
@echo off
for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i
pause
用這條命令搜索文件真不錯(cuò)。。。。。。
這個(gè)參數(shù)大家應(yīng)該理解了吧!還是滿好玩的命令!


四、參數(shù) /L
FOR /L %%variable IN (start,step,end) DO command [command-parameters]
    該集表示以增量形式從開始到結(jié)束的一個(gè)數(shù)字序列。
    因此，(1,1,5) 將產(chǎn)生序列 1 2 3 4 5，(5,-1,1) 將產(chǎn)生
    序列 (5 4 3 2 1)。
使 用迭代變量設(shè)置起始值 (Start#)，然后逐步執(zhí)行一組范圍的值，直到該值超過所設(shè)置的終止值 (End#)。/L 將通過對 Start# 與 End# 進(jìn)行比較來執(zhí)行迭代變量。如果 Start# 小于 End#，就會(huì)執(zhí)行該命令。如果迭代變量超過 End#，則命令解釋程序退出此循環(huán)。還可以使用負(fù)的 Step# 以遞減數(shù)值的方式逐步執(zhí)行此范圍內(nèi)的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 則生成序列 (5 4 3 2 1)。語法是：
看著這說明有點(diǎn)暈吧!咱們看例子就不暈了!
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存執(zhí)行看效果,他會(huì)打印從1 2 3 4 5  這樣5個(gè)數(shù)字
(1,1,5)這個(gè)參數(shù)也就是表示從1開始每次加1直到5終止!
等會(huì)暈,就打印個(gè)數(shù)字有P用...好的滿足大家,看這個(gè)例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause
執(zhí)行后是不是嚇了一跳,怎么多了5個(gè)CMD窗口,呵呵!如果把那個(gè) (1,1,5)改成 (1,1,65535)會(huì)有什么結(jié)果,我先告訴大家,會(huì)打開65535個(gè)CMD窗口....這么多你不死機(jī)算你強(qiáng)!
當(dāng)然我們也可以把那個(gè)start cmd改成md %%i 這樣就會(huì)建立指定個(gè)目錄了!!!名字為1-65535
看完這個(gè)被我賦予破壞性質(zhì)的參數(shù)后,我們來看最后一個(gè)參數(shù)

五、參數(shù) /F
\迭代及文件解析
使用文件解析來處理命令輸出、字符串及文件內(nèi)容。使用迭代變量定義要檢查的內(nèi)容或字符串，并使用各種options選項(xiàng)進(jìn)一步修改解析方式。使用options令牌選項(xiàng)指定哪些令牌應(yīng)該作為迭代變量傳遞。請注意：在沒有使用令牌選項(xiàng)時(shí)，/F 將只檢查第一個(gè)令牌。
文件解析過程包括讀取輸出、字符串或文件內(nèi)容，將其分成獨(dú)立的文本行以及再將每行解析成零個(gè)或更多個(gè)令牌。然后通過設(shè)置為令牌的迭代變量值，調(diào)用 for 循環(huán)。默認(rèn)情況下，/F 傳遞每個(gè)文件每一行的第一個(gè)空白分隔符號(hào)。跳過空行。

詳細(xì)的幫助格式為：
FOR /F ["options"] %%variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %%variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %%variable IN ('command') DO command [command-parameters]
    帶引號(hào)的字符串"options"包括一個(gè)或多個(gè)
    指定不同解析選項(xiàng)的關(guān)鍵字。這些關(guān)鍵字為:
        eol=c           - 指一個(gè)行注釋字符的結(jié)尾(就一個(gè))(備注：默認(rèn)以使用；號(hào)為行首字符的為注釋行)
        skip=n          - 指在文件開始時(shí)忽略的行數(shù)，(備注：最小為1，n可以大于文件的總行數(shù)，默認(rèn)為1。)
        delims=xxx      - 指分隔符集。這個(gè)替換了空格和跳格鍵的默認(rèn)分隔符集。
        tokens=x,y,m-n  - 指每行的哪一個(gè)符號(hào)被傳遞到每個(gè)迭代
                          的 for 本身。這會(huì)導(dǎo)致額外變量名稱的分配。m-n
                          格式為一個(gè)范圍。通過 nth 符號(hào)指定 mth。如果
                          符號(hào)字符串中的最后一個(gè)字符星號(hào)，
                          那么額外的變量將在最后一個(gè)符號(hào)解析之后
                          分配并接受行的保留文本。經(jīng)測試，該參數(shù)最多
                          只能區(qū)分31個(gè)字段。(備注：默認(rèn)為1，則表示只顯示分割后的第一列的內(nèi)容，最大是31，超過最大則無法表示)
        usebackq        - 使用后引號(hào)（鍵盤上數(shù)字1左面的那個(gè)鍵`）。
                        未使用參數(shù)usebackq時(shí)：file-set表示文件，但不能含有空格
                            雙引號(hào)表示字符串，即"string"
                            單引號(hào)表示執(zhí)行命令，即'command'
                          使用參數(shù)usebackq時(shí)：file-set和"file-set"都表示文件
                          當(dāng)文件路徑或名稱中有空格時(shí)，就可以用雙引號(hào)括起來
                            單引號(hào)表示字符串，即'string'
                            后引號(hào)表示命令執(zhí)行，即`command`

以上是用for /?命令獲得的幫助信息，直接復(fù)制過來的，括號(hào)中的備注為我添加的說明。
暈慘了!我這就舉個(gè)例子幫助大家來理解這些參數(shù)!

For命令例1：****************************************
@echo off
rem 首先建立臨時(shí)文件test.txt
echo ;注釋行,這是臨時(shí)文件,用完刪除 >test.txt
echo 11段 12段 13段 14段 15段 16段 >>test.txt
echo 21段,22段,23段,24段,25段,26段 >>test.txt
echo 31段-32段-33段-34段-35段-36段 >>test.txt
FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k
Pause
Del test.txt
運(yùn)行顯示結(jié)果：
11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
請按任意鍵繼續(xù). . .
為什么會(huì)這樣?我來解釋：
eol=;          分號(hào)開頭的行為注釋行
tokens=1,3*    將每行第1段,第3段和剩余字段分別賦予變量%%i，%%j，%%k
delims=,-     （減號(hào)后有一空格）以逗號(hào)減號(hào)和空格為分隔符，空格必須放在最后

For命令例2：****************************************
@echo off
FOR /F "eol= delims=" %%i in (test.txt) do echo %%i
Pause
運(yùn)行將顯示test.txt全部內(nèi)容，包括注釋行，不解釋了哈。

For命令例3：****************************************
另外/F參數(shù)還可以以輸出命令的結(jié)果看這個(gè)例子
@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause
這樣你本機(jī)全部帳號(hào)名字就出來了把擴(kuò)號(hào)內(nèi)的內(nèi)容用兩個(gè)單引號(hào)引起來就表示那個(gè)當(dāng)命令執(zhí)行,FOR會(huì)返回命令的每行結(jié)果,加那個(gè)"delims=" 是為了讓我空格的行能整行顯示出來,不加就只顯示空格左邊一列!

基本上講完了FOR的基本用法了...如果你看過FOR的系統(tǒng)幫助,你會(huì)發(fā)現(xiàn)他下面還有一些特定義的變量,這些我先不講.大家因該都累了吧!你不累我累啊....
所謂文武之道，一張一弛，現(xiàn)休息一下。



＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
第三章 FOR命令中的變量
FOR命令中有一些變量,他們的用法許多新手朋友還不太了解,今天給大家講解他們的用法!

先把FOR的變量全部列出來:
     ~I          - 刪除任何引號(hào)(")，擴(kuò)展 %I
     %~fI        - 將 %I 擴(kuò)展到一個(gè)完全合格的路徑名
     %~dI        - 僅將 %I 擴(kuò)展到一個(gè)驅(qū)動(dòng)器號(hào)
     %~pI        - 僅將 %I 擴(kuò)展到一個(gè)路徑
     %~nI        - 僅將 %I 擴(kuò)展到一個(gè)文件名
     %~xI        - 僅將 %I 擴(kuò)展到一個(gè)文件擴(kuò)展名
     %~sI        - 擴(kuò)展的路徑只含有短名
     %~aI        - 將 %I 擴(kuò)展到文件的文件屬性
     %~tI        - 將 %I 擴(kuò)展到文件的日期/時(shí)間
     %~zI        - 將 %I 擴(kuò)展到文件的大小
     %~$PATH:I   - 查找列在路徑環(huán)境變量的目錄，并將 %I 擴(kuò)展
                   到找到的第一個(gè)完全合格的名稱。如果環(huán)境變量名
                   未被定義，或者沒有找到文件，此組合鍵會(huì)擴(kuò)展到
                   空字符串

我們可以看到每行都有一個(gè)大寫字母"I",這個(gè)I其實(shí)就是我們在FOR帶入的變量,我們FOR語句代入的變量名是什么,這里就寫什么.
比如:FOR /F  %%z IN ('set') DO @echo %%z
這里我們代入的變量名是z那么我們就要把那個(gè)I改成z,例如%~fI改為%~fz
至于前面的%~p這樣的內(nèi)容就是語法了!

好開始講解:

一、 ~I          - 刪除任何引號(hào)(")，擴(kuò)展 %I
這個(gè)變量的作用就如他的說明,刪除引號(hào)!
我們來看這個(gè)例子:
首先建立臨時(shí)文件temp.txt，內(nèi)容如下
"1111
"2222"
3333"
"4444"44
"55"55"55
可建立個(gè)BAT文件代碼如下:
@echo off
echo ^"1111>temp.txt
echo "2222">>temp.txt
echo 3333^">>temp.txt
echo "4444"44>>temp.txt
echo ^"55"55"55>>temp.txt
rem 上面建立臨時(shí)文件，注意不成對的引號(hào)要加轉(zhuǎn)義字符^，重定向符號(hào)前不要留空格
FOR /F "delims=" %%i IN (temp.txt) DO echo  %%~i
pause
del temp.txt
執(zhí)行后,我們看CMD的回顯如下:
1111           #字符串前的引號(hào)被刪除了
2222           #字符串首尾的引號(hào)都被刪除了
3333"          #字符串前無引號(hào)，后面的引號(hào)保留
4444"44        #字符串前面的引號(hào)刪除了，而中間的引號(hào)保留
55"55"55       #字符串前面的引號(hào)刪除了，而中間的引號(hào)保留
請按任意鍵繼續(xù). . .
和之前temp.txt中的內(nèi)容對比一下,我們會(huì)發(fā)現(xiàn)第1、2、5行的引號(hào)都消失了,這就是刪除引號(hào)~i的作用了!
刪除引號(hào)規(guī)則如下(BAT兄補(bǔ)充!)
1、若字符串首尾同時(shí)存在引號(hào)，則刪除首尾的引號(hào)；
2、若字符串尾不存在引號(hào)，則刪除字符串首的引號(hào)；
3、如果字符串中間存在引號(hào)，或者只在尾部存在引號(hào)，則不刪除。
龍卷風(fēng)補(bǔ)充：無頭不刪，有頭連尾刪。


二、 %~fI        - 將 %I 擴(kuò)展到一個(gè)完全合格的路徑名
看例子:
把代碼保存放在隨便哪個(gè)地方,我這里就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~fi
pause
執(zhí)行后顯示內(nèi)容如下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
當(dāng)我把代碼中的 %%~fi直接改成%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%i
pause
執(zhí)行后就會(huì)顯示以下內(nèi)容：
test.bat
test.vbs
通過對比,我們很容易就看出沒有路徑了,這就是"將 %I 擴(kuò)展到一個(gè)完全合格的路徑名"的作用
也就是如果%i變量的內(nèi)容是一個(gè)文件名的話,他就會(huì)把這個(gè)文件所在的絕對路徑打印出來,而不只單單打印一個(gè)文件名,自己動(dòng)手動(dòng)實(shí)驗(yàn)下就知道了!


三、 %~dI        - 僅將 %I 擴(kuò)展到一個(gè)驅(qū)動(dòng)器號(hào)
看例子:
代碼如下,我還是放到桌面執(zhí)行!
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~di
pause
執(zhí)行后我CMD里顯示如下
C:
C:
我桌面就兩個(gè)文件test.bat,test.vbs,%%~di作用是,如果變量%%i的內(nèi)容是一個(gè)文件或者目錄名,他就會(huì)把他這文件
或者目錄所在的盤符號(hào)打印出來!


四、 %~pI        - 僅將 %I 擴(kuò)展到一個(gè)路徑
這個(gè)用法和上面一樣,他只打印路徑不打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~pi
pause
我就不打結(jié)果了,大家自己復(fù)制代碼看結(jié)果吧,下面幾個(gè)都是這么個(gè)用法,代碼給出來,大家自己看結(jié)果吧!


五、 %~nI        - 僅將 %I 擴(kuò)展到一個(gè)文件名
只打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ni
pause


六、 %~xI        - 僅將 %I 擴(kuò)展到一個(gè)文件擴(kuò)展名
只打印文件的擴(kuò)展名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~xi
pause


七、 %~sI        - 擴(kuò)展的路徑只含有短名
打印絕對短文件名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~si
pause


八、 %~aI        - 將 %I 擴(kuò)展到文件的文件屬性
打印文件的屬性
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ai
pause


九、 %~tI        - 將 %I 擴(kuò)展到文件的日期/時(shí)間
打印文件建立的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ti
pause

十、 %~zI        - 將 %I 擴(kuò)展到文件的大小
打印文件的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~zi
pause
上面例子中的"delims=="可以改為"delims="，即不要分隔符


十一、 %~$PATH:I - 查找列在路徑環(huán)境變量的目錄

并將 %I 擴(kuò)展到找到的第一個(gè)完全合格的名稱。如果環(huán)境變量名未被定義，或者沒有找到文件，此組合鍵會(huì)擴(kuò)展到空字符串
這是最后一個(gè),和上面那些都不一樣,我單獨(dú)說說!

然后在把這些代碼保存為批處理,放在桌面。
@echo off
FOR /F "delims=" %%i IN (“notepad.exe”) DO echo  %%~$PATH:i
pause
龍卷風(fēng)補(bǔ)充：上面代碼顯示結(jié)果為C:\WINDOWS\system32\notepad.exe
他的意思就在PATH變量里指定的路徑里搜索notepad.exe文件，如果有notepad.exe則會(huì)把他所在絕對路徑打印出來，沒有就打印一個(gè)錯(cuò)誤！

好了,FOR的的變量就介紹到這了!
                               

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝                   
第四章 批處理中的變量
批處理中的變量,我把他分為兩類,分別為"系統(tǒng)變量"和"自定義變量"
我們現(xiàn)在來詳解這兩個(gè)變量!

一、系統(tǒng)變量
他們的值由系統(tǒng)將其根據(jù)事先定義的條件自動(dòng)賦值,也就是這些變量系統(tǒng)已經(jīng)給他們定義了值,
不需要我們來給他賦值,我們只需要調(diào)用而以!  我把他們?nèi)苛谐鰜?

%ALLUSERSPROFILE% 本地 返回“所有用戶”配置文件的位置。
%APPDATA% 本地 返回默認(rèn)情況下應(yīng)用程序存儲(chǔ)數(shù)據(jù)的位置。
%CD% 本地 返回當(dāng)前目錄字符串。
%CMDCMDLINE% 本地 返回用來啟動(dòng)當(dāng)前的 Cmd.exe 的準(zhǔn)確命令行。
%CMDEXTVERSION% 系統(tǒng) 返回當(dāng)前的“命令處理程序擴(kuò)展”的版本號(hào)。
%COMPUTERNAME%  系統(tǒng) 返回計(jì)算機(jī)的名稱。
%COMSPEC%  系統(tǒng) 返回命令行解釋器可執(zhí)行程序的準(zhǔn)確路徑。
%DATE%  系統(tǒng) 返回當(dāng)前日期。使用與 date /t 命令相同的格式。由 Cmd.exe 生成。有關(guān)
date 命令的詳細(xì)信息，請參閱 Date。
%ERRORLEVEL%  系統(tǒng) 返回上一條命令的錯(cuò)誤代碼。通常用非零值表示錯(cuò)誤。
%HOMEDRIVE%  系統(tǒng) 返回連接到用戶主目錄的本地工作站驅(qū)動(dòng)器號(hào)?；谥髂夸浿刀O(shè)置。用
戶主目錄是在“本地用戶和組”中指定的。
%HOMEPATH%  系統(tǒng) 返回用戶主目錄的完整路徑?；谥髂夸浿刀O(shè)置。用戶主目錄是在“本地用戶和組”中指定的。
%HOMESHARE%  系統(tǒng) 返回用戶的共享主目錄的網(wǎng)絡(luò)路徑?；谥髂夸浿刀O(shè)置。用戶主目錄是
在“本地用戶和組”中指定的。
%LOGONSERVER%  本地 返回驗(yàn)證當(dāng)前登錄會(huì)話的域控制器的名稱。
%NUMBER_OF_PROCESSORS%  系統(tǒng) 指定安裝在計(jì)算機(jī)上的處理器的數(shù)目。
%OS%  系統(tǒng) 返回操作系統(tǒng)名稱。Windows 2000 顯示其操作系統(tǒng)為 Windows_NT。
%PATH% 系統(tǒng) 指定可執(zhí)行文件的搜索路徑。
%PATHEXT% 系統(tǒng) 返回操作系統(tǒng)認(rèn)為可執(zhí)行的文件擴(kuò)展名的列表。
%PROCESSOR_ARCHITECTURE%  系統(tǒng) 返回處理器的芯片體系結(jié)構(gòu)。值：x86 或 IA64 基于
Itanium
%PROCESSOR_IDENTFIER% 系統(tǒng) 返回處理器說明。
%PROCESSOR_LEVEL%  系統(tǒng) 返回計(jì)算機(jī)上安裝的處理器的型號(hào)。
%PROCESSOR_REVISION% 系統(tǒng) 返回處理器的版本號(hào)。
%PROMPT% 本地 返回當(dāng)前解釋程序的命令提示符設(shè)置。由 Cmd.exe 生成。
%RANDOM% 系統(tǒng) 返回 0 到 32767 之間的任意十進(jìn)制數(shù)字。由 Cmd.exe 生成。
%SYSTEMDRIVE% 系統(tǒng) 返回包含 Windows server operating system 根目錄（即系統(tǒng)根目錄）
的驅(qū)動(dòng)器。
%SYSTEMROOT%  系統(tǒng) 返回 Windows server operating system 根目錄的位置。
%TEMP% 和 %TMP% 系統(tǒng)和用戶 返回對當(dāng)前登錄用戶可用的應(yīng)用程序所使用的默認(rèn)臨時(shí)目錄。
有些應(yīng)用程序需要 TEMP，而其他應(yīng)用程序則需要 TMP。
%TIME% 系統(tǒng) 返回當(dāng)前時(shí)間。使用與 time /t 命令相同的格式。由 Cmd.exe 生成。有關(guān)
time 命令的詳細(xì)信息，請參閱 Time。
%USERDOMAIN% 本地 返回包含用戶帳戶的域的名稱。
%USERNAME% 本地 返回當(dāng)前登錄的用戶的名稱。
%USERPROFILE% 本地 返回當(dāng)前用戶的配置文件的位置。
%WINDIR% 系統(tǒng) 返回操作系統(tǒng)目錄的位置。

這么多系統(tǒng)變量,我們?nèi)绾沃浪闹凳鞘裁茨?
在CMD里輸入  echo %WINDIR%
這樣就能顯示一個(gè)變量的值了!
舉個(gè)實(shí)際例子,比如我們要復(fù)制文件到當(dāng)前帳號(hào)的啟動(dòng)目錄里就可以這樣
copy d:\1.bat "%USERPROFILE%\「開始」菜單\程序\啟動(dòng)\"
%USERNAME% 本地 返回當(dāng)前登錄的用戶的名稱。  注意有空格的目錄要用引號(hào)引起來

另外還有一些系統(tǒng)變量,他們是代表一個(gè)意思,或者一個(gè)操作!
他們分別是%0 %1 %2 %3 %4 %5 ......一直到%9 還有一個(gè)%*
%0 這個(gè)有點(diǎn)特殊,有幾層意思,先講%1-%9的意思.
%1 返回批處理的第一個(gè)參數(shù)
%2 返回批處理的第二個(gè)參數(shù)
%3-%9依此推類
反回批處理參數(shù)?到底怎么個(gè)返回法?
我們看這個(gè)例子,把下面的代碼保存為test.BAT然后放到C盤下
@echo off
echo %1 %2 %3 %4
echo %1
echo %2
echo %3
echo %4
進(jìn)入CMD,輸入cd c:\
然后輸入 test.bat 我是第一個(gè)參數(shù) 我是第二個(gè)參數(shù)  我是第三個(gè)參數(shù)  我是第四個(gè)參數(shù)
注意中間的空格,我們會(huì)看到這樣的結(jié)果:
我是第一個(gè)參數(shù) 我是第二個(gè)參數(shù) 我是第三個(gè)參數(shù) 我是第四個(gè)參數(shù)
我是第一個(gè)參數(shù)
我是第二個(gè)參數(shù)
我是第三個(gè)參數(shù)
我是第四個(gè)參數(shù)
對比下代碼,%1就是”我是第一個(gè)參數(shù)”  %2就是”我是第二個(gè)參數(shù)”
怎么樣理解了吧!

這些%1和%9可以讓批處理也能帶參數(shù)運(yùn)行,大大提高批處理功能!

還有一個(gè)%*  他是什么呢?他的作用不是很大,只是返回參數(shù)而已,不過他是一次返回全部參數(shù)的值,不用在輸入%1 %2來確定一個(gè)個(gè)的

例子
@echo off
echo %*
同樣保存為test.bat 放到C盤
進(jìn)入CMD,輸入cd c:\
然后輸入 test.bat 我是第一個(gè)參數(shù) 我是第二個(gè)參數(shù)  我是第三個(gè)參數(shù)  我是第四個(gè)參數(shù)
可以看到他一次把全部參數(shù)都顯示出來了

好現(xiàn)在開始講那個(gè)比較特殊的%0

%0  這個(gè)不是返回參數(shù)的值了,他有兩層意思!
第一層意思:返回批處理所在絕對路徑
例子:
@echo off
echo %0
pause
保存為test.BAT放在桌面運(yùn)行,會(huì)顯示如下結(jié)果
"C:\Documents and Settings\Administrator\桌面\test.bat"
他把當(dāng)前批處理執(zhí)行的所在路經(jīng)打印出來了,這就是返回批處理所在絕對路徑的意思
第二層意思:無限循環(huán)執(zhí)行BAT
例子:
@echo off
net user
%0
保存為BAT執(zhí)行,他就會(huì)無限循環(huán)執(zhí)行net user這條命令,直到你手動(dòng)停止.
龍卷風(fēng)補(bǔ)充：其實(shí)%0就是第一參數(shù)%1前面那個(gè)參數(shù)，當(dāng)然就是批處理文件名（包括路徑）。
以上就是批處理中的一些系統(tǒng)變量,另外還有一些變量,他們也表示一些功能,
FOR命令中的那些就是,FOR變量已經(jīng)說過,就不講了.


二、自定義變量
故名思意,自定義變量就是由我們來給他賦予值的變量
要使用自定義變量就得使用set命令了,看例子.
@echo off
set var=我是值
echo %var%
pause
保存為BAT執(zhí)行,我們會(huì)看到CMD里返回一個(gè)  "我是值"
var為變量名,=號(hào)右變的是要給變量的值
這就是最簡單的一種設(shè)置變量的方法了
如果我們想讓用戶手工輸入變量的值,而不是在代碼里指定,可以用用set命令的/p參數(shù)
例子:
@echo off
set /p var=請輸入變量的值
echo %var%
pause
var變量名  =號(hào)右邊的是提示語,不是變量的值
變量的值由我們運(yùn)行后自己用鍵盤輸入! 

一、交互界面設(shè)計(jì)

沒啥說的，看看高手設(shè)計(jì)的菜單界面吧：
@echo off
cls
title 終極多功能修復(fù)
:menu
cls
color 0A
echo.
echo                 ==============================
echo                 請選擇要進(jìn)行的操作，然后按回車
echo                 ==============================
echo.
echo              1.網(wǎng)絡(luò)修復(fù)及上網(wǎng)相關(guān)設(shè)置,修復(fù)IE,自定義屏蔽網(wǎng)站
echo.
echo              2.病毒專殺工具，端口關(guān)閉工具,關(guān)閉自動(dòng)播放
echo.
echo              3.清除所有多余的自啟動(dòng)項(xiàng)目，修復(fù)系統(tǒng)錯(cuò)誤
echo.
echo              4.清理系統(tǒng)垃圾,提高啟動(dòng)速度
echo.
echo              Q.退出
echo.
echo.
:cho
set choice=
set /p choice=          請選擇:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 選擇無效，請重新輸入
echo.
goto cho
只要學(xué)完本教程前面的章節(jié)，上面的程序應(yīng)該能看懂了。





二、if…else…條件語句

前面已經(jīng)談到，DOS條件語句主要有以下形式
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
增強(qiáng)用法：IF [/I] string1 compare-op string2 command
增強(qiáng)用法中加上/I就不區(qū)分大小寫了!
增強(qiáng)用法中還有一些用來判斷數(shù)字的符號(hào)：

EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于


上面的command命令都可以用小括號(hào)來使用多條命令的組合，包括else子句，組合命令中可以嵌套使用條件或循環(huán)命令。

例如:

    IF EXIST filename (
        del filename
    ) ELSE (
        echo filename missing
    )

也可寫成：
if exist filename (del filename) else (echo filename missing)
但這種寫法不適合命令太多或嵌套命令的使用。注意：else必須和if在同一行，或者和if最后的括號(hào)在同一行，如： ......) ELSE (......。在括號(hào)那換行程序認(rèn)為是一條語句。


三、循環(huán)語句

1、指定次數(shù)循環(huán)
FOR /L %variable IN (start,step,end) DO command [command-parameters]

組合命令：
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
) 

2、對某集合執(zhí)行循環(huán)語句。
FOR %%variable IN (set) DO command [command-parameters]

  %%variable  指定一個(gè)單一字母可替換的參數(shù)。
  (set)      指定一個(gè)或一組文件?？梢允褂猛ㄅ浞?。
  command   對每個(gè)文件執(zhí)行的命令，可用小括號(hào)使用多條命令組合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

    檢查以 [drive:]path 為根的目錄樹，指向每個(gè)目錄中的
    FOR 語句。如果在 /R 后沒有指定目錄，則使用當(dāng)前
目錄。如果集僅為一個(gè)單點(diǎn)(.)字符，則枚舉該目錄樹。

同前面一樣，command可以用括號(hào)來組合：
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

3、條件循環(huán)
    上面的循環(huán)結(jié)構(gòu)是用for命令來實(shí)現(xiàn)的，for命令循環(huán)有一個(gè)缺點(diǎn)，就是整個(gè)循環(huán)被當(dāng)作一條命令語句，涉及到變量延遲的問題。
    利用goto語句和條件判斷，dos可以實(shí)現(xiàn)條件循環(huán)，很簡單啦，看例子：

例：
@echo off
set var=0
rem ************循環(huán)開始了
:continue
set /a var+=1
echo 第%var%次循環(huán)
if %var% lss 100 goto continue
rem ************循環(huán)結(jié)束了
echo 循環(huán)執(zhí)行完畢
pause

例：
@echo off
set var=100
rem ************循環(huán)開始了
:continue
echo 第%var%次循環(huán)
set /a var-=1
if %var% gtr 0 goto continue
rem ************循環(huán)結(jié)束了
echo 循環(huán)執(zhí)行完畢
pause





四、子程序

在批處理程序中可以調(diào)用外部可運(yùn)行程序，比如exe程序，也可調(diào)用其他批處理程序，這些也可以看作子程序，但是不夠方便，如果被調(diào)用的程序很多，就顯得不夠簡明了，很繁瑣。
   在windowsXP中，批處理可以調(diào)用本程序中的一個(gè)程序段，相當(dāng)于子程序，這些子程序一般放在主程序后面。

子程序調(diào)用格式：
  CALL :label arguments

子程序語法：
  :label
  command1
  command2
  ......
  commandn
  goto :eof

在子程序段中，參數(shù)%0指標(biāo)簽:label

子過程一般放在最后，并且注意在主程序最后要加上exit或跳轉(zhuǎn)語句，避免錯(cuò)誤的進(jìn)入子過程。

子程序和主程序中的變量都是全局變量，其作用范圍都是整個(gè)批處理程序。

傳至子程序的參數(shù)在call語句中指定，在子程序中用%1、%2至%9的形式調(diào)用，而子程序返回主程序的數(shù)據(jù)只需在調(diào)用結(jié)束后直接引用就可以了，當(dāng)然也可以指定返回變量，請看下面的例子。

子程序例1：
@echo off
call :sub return
echo 子程序返回值：%return%
pause
goto :eof

:sub
set %1=你好
goto :eof
運(yùn)行結(jié)果：你好



子程序例2：設(shè)計(jì)一個(gè)求多個(gè)整數(shù)相加的子程序
@echo off
set sum=0
call :sub 10 20 35 40 50
echo 數(shù)據(jù)求和結(jié)果：%sum%
pause
goto :eof

:sub
rem 參數(shù)1為返回變量名稱
set /a sum+=%1
shift /1 
if not "%1"=="" goto sub
goto :eof

運(yùn)行結(jié)果：155

五、用ftp命令實(shí)現(xiàn)自動(dòng)下載

ftp是常用的下載工具，ftp界面中有40多個(gè)常用命令，自己學(xué)習(xí)了，不介紹了。這里介紹如何用dos命令行調(diào)用ftp命令，實(shí)現(xiàn)ftp自動(dòng)登錄，并上傳下載，并自動(dòng)退出ftp程序。
其實(shí)可以將ftp命令組合保存為一個(gè)文本文件，然后用以下命令調(diào)用即可。

ftp  -n -s:[[drive:]path]filename

上面的filename為ftp命令文件，包括登錄IP地址，用戶名、密碼、操作命令等
例：
open 90.52.8.3   ＃打開ip
user iware       ＃用戶為iware
password8848    ＃密碼
bin             ＃二進(jìn)制傳輸模式
prompt
cd tmp1         ＃切換至iware用戶下的tmp1目錄
pwd
lcd d:\download   ＃本地目錄
mget *          ＃下載tmp1目錄下的所有文件
bye             ＃退出ftp




六、用7-ZIP實(shí)現(xiàn)命令行壓縮和解壓功能

語法格式：（詳細(xì)情況見7-zip幫助文件，看得頭暈可以跳過，用到再學(xué)）
7z <command> [<switch>...] <base_archive_name> [<arguments>...]

7z.exe的每個(gè)命令都有不同的參數(shù)<switch>,請看幫助文件
<base_archive_name>為壓縮包名稱
<arguments>為文件名稱，支持通配符或文件列表

其中，7z是至命令行壓縮解壓程序7z.exe，<command>是7z.exe包含的命令，列舉如下：

a： Adds files to archive. 添加至壓縮包
a命令可用參數(shù)：
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -sfx (create SFX)
  -si (use StdIn)
  -so (use StdOut)
  -ssw (Compress shared files)
  -t (Type of archive)
  -u (Update)
  -v (Volumes)
  -w (Working Dir)
  -x (Exclude) 

b： Benchmark 
d： Deletes files from archive. 從壓縮包中刪除文件
d命令可用參數(shù)：
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -u (Update)
  -w (Working Dir)
  -x (Exclude) 

e： Extract解壓文件至當(dāng)前目錄或指定目錄
e命令可用參數(shù)：
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries) 

l： Lists contents of archive.
t： Test 
u： Update 

x： eXtract with full paths用文件的完整路徑解壓至當(dāng)前目錄或指定目錄
x命令可用參數(shù)：
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries) 




七、調(diào)用VBScript程序

使用 Windows 腳本宿主，可以在命令提示符下運(yùn)行腳本。CScript.exe 提供了用于設(shè)置腳本屬性的命令行開關(guān)。

用法：CScript 腳本名稱 [腳本選項(xiàng)...] [腳本參數(shù)...]
選項(xiàng)：
//B       批模式：不顯示腳本錯(cuò)誤及提示信息
//D       啟用 Active Debugging
//E:engine   使用執(zhí)行腳本的引擎
//H:CScript 將默認(rèn)的腳本宿主改為 CScript.exe
//H:WScript 將默認(rèn)的腳本宿主改為 WScript.exe （默認(rèn)）
//I       交互模式（默認(rèn)，與 //B 相對)
//Job:xxxx   執(zhí)行一個(gè) WSF 工作
//Logo    顯示徽標(biāo)（默認(rèn)）
//Nologo 不顯示徽標(biāo)：執(zhí)行時(shí)不顯示標(biāo)志
//S       為該用戶保存當(dāng)前命令行選項(xiàng)
//T:nn    超時(shí)設(shè)定秒：允許腳本運(yùn)行的最長時(shí)間
//X       在調(diào)試器中執(zhí)行腳本
//U       用 Unicode 表示來自控制臺(tái)的重定向 I/O

“腳本名稱”是帶有擴(kuò)展名和必需的路徑信息的腳本文件名稱，如d:/admin/vbscripts/chart.vbs。
“腳本選項(xiàng)和參數(shù)”將傳遞給腳本。腳本參數(shù)前面有一個(gè)斜杠 (/)。每個(gè)參數(shù)都是可選的；但不能在未指定腳本名稱的情況下指定腳本選項(xiàng)。如果未指定參數(shù)，則 CScript 將顯示 CScript 語法和有效的宿主參數(shù)。




八、將批處理轉(zhuǎn)化為可執(zhí)行文件

由于批處理文件是一種文本文件，任何人都可以對其進(jìn)行隨便編輯，不小心就會(huì)把里面的命令破壞掉，所以如果將其轉(zhuǎn)換成.com格式的可執(zhí)行文件，不僅執(zhí)行效率會(huì)大大提高，而且不會(huì)破壞原來的功能，更能將優(yōu)先級(jí)提到最高。Bat2Com就可以完成這個(gè)轉(zhuǎn)換工作。
小 知識(shí)：在DOS環(huán)境下，可執(zhí)行文件的優(yōu)先級(jí)由高到低依次為.com>.exe>.bat>.cmd，即如果在同一目錄下存在文件名相同 的這四類文件，當(dāng)只鍵入文件名時(shí)，DOS執(zhí)行的是name.com，如果需要執(zhí)行其他三個(gè)文件，則必須指定文件的全名，如name.bat。

這是一個(gè)只有5.43K大小的免費(fèi)綠色工具，可以運(yùn)行在純DOS或DOS窗口的命令行中，用法：Bat2Com
FileName，這樣就會(huì)在同一目錄下生成一個(gè)名為FileNme.com的可執(zhí)行文件，執(zhí)行的效果和原來的.bat文件一樣。

九、時(shí)間延遲

本條參考引用[英雄]教程
什么是時(shí)間延遲？顧名思義，就是執(zhí)行一條命令后延遲一段時(shí)間再進(jìn)行下一條命令。
延遲的應(yīng)用見下節(jié)：“模擬進(jìn)度條”。
1、利用ping命令延時(shí)
例：
  @echo off
  echo 延時(shí)前：%time%
  ping /n 3 127.0.0.1 >nul
  echo 延時(shí)后：%time%
  pause 
解說：用到了ping命令的“/n”參數(shù)，表示要發(fā)送多少次請求到指定的ip。本例中要發(fā)送3次請求到本機(jī)的ip（127.0.0.1）。127.0.0.1可簡寫為127.1?！?gt;nul”就是屏蔽掉ping命令所顯示的內(nèi)容。

2、利用for命令延時(shí)
例：
  @echo off
  echo 延時(shí)前：%time%
  for /l %%i in (1,1,5000) do echo %%i>nul
  echo 延時(shí)后：%time%
  pause
解說：原理很簡單，就是利用一個(gè)計(jì)次循環(huán)并屏蔽它所顯示的內(nèi)容來達(dá)到延時(shí)的目的。

3、利用vbs延遲函數(shù)，精確度毫秒，誤差1000毫秒內(nèi)

例：

@echo off
echo %time%
call :delay 5000
echo %time%
pause

exit
:delay
echo WScript.Sleep %1>delay.vbs
CScript //B delay.vbs
del delay.vbs
goto :eof

運(yùn)行顯示：

10:44:06.45
10:44:11.95
請按任意鍵繼續(xù). . .

上面的運(yùn)行結(jié)果顯示實(shí)際延時(shí)了5500毫秒，多出來的500毫秒時(shí)建立和刪除臨時(shí)文件所耗費(fèi)的時(shí)間。誤差在一秒之內(nèi)。


4、僅用批處理命令實(shí)現(xiàn)任意時(shí)間延遲，精確度10毫秒，誤差50毫秒內(nèi)

僅用批處理命令就可以實(shí)現(xiàn)延遲操作。

例：

@echo off
set /p delay=請輸入需延遲的毫秒數(shù)：
set TotalTime=0
set NowTime=%time%
::讀取起始時(shí)間，時(shí)間格式為：13:01:05.95
echo 程序開始時(shí)間：%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::讀取起始時(shí)間的分鐘數(shù)
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將起始時(shí)間的秒數(shù)轉(zhuǎn)為毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 讀取現(xiàn)在時(shí)間的分鐘數(shù)
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將現(xiàn)在時(shí)間的秒數(shù)轉(zhuǎn)為毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序結(jié)束時(shí)間：%time%
echo 設(shè)定延遲時(shí)間：%delay%毫秒
echo 實(shí)際延遲時(shí)間：%TotalTime%毫秒
pause

運(yùn)行顯示：

   請輸入需延遲的毫秒數(shù)：6000
   程序開始時(shí)間：15:32:16.37
   程序結(jié)束時(shí)間：15:32:22.37
   設(shè)定延遲時(shí)間：6000毫秒
   實(shí)際延遲時(shí)間：6000毫秒
   請按任意鍵繼續(xù). . .

實(shí)現(xiàn)原理：首先設(shè)定要延遲的毫秒數(shù)，然后用循環(huán)累加時(shí)間，直到累加時(shí)間大于等于延遲時(shí)間。

誤差：windows系統(tǒng)時(shí)間只能精確到10毫秒，所以理論上有可能存在10毫秒誤差。
      經(jīng)測試，當(dāng)延遲時(shí)間大于500毫秒時(shí)，上面的延遲程序一般不存在誤差。當(dāng)延遲時(shí)間小于500毫秒時(shí)，可能有幾十毫秒誤差，為什么？因?yàn)檠舆t程序本身也是有運(yùn)行時(shí)間的，同時(shí)系統(tǒng)時(shí)間只能精確到10毫秒。

為了方便引用，可將上面的例子改為子程序調(diào)用形式：

@echo off
echo 程序開始時(shí)間：%Time%
call :delay 10
echo 實(shí)際延遲時(shí)間：%totaltime%毫秒
echo 程序結(jié)束時(shí)間：%time%
pause
exit

::-----------以下為延時(shí)子程序--------------------
:delay
@echo off
if "%1"=="" goto :eof
set DelayTime=%1
set TotalTime=0
set NowTime=%time%
::讀取起始時(shí)間，時(shí)間格式為：13:01:05.95
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %DelayTime% goto delay_continue
goto :eof






十、模擬進(jìn)度條

下面給出一個(gè)模擬進(jìn)度條的程序。如果將它運(yùn)用在你自己的程序中，可以使你的程序更漂亮。

@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo  程序正在初始化. . . 
echo.
echo  ┌──────────────────────────────────────┐
set/p=  ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo   100%%
echo  └──────────────────────────────────────┘
pause

解說：“set /p a=■<nul”的意思是：只顯示提示信息“■”且不換行，也不需手工輸入任何信息，這樣可以使每個(gè)“■”在同一行逐個(gè)輸出?！皃ing /n 0 127.1>nul”是輸出每個(gè)“■”的時(shí)間間隔，ping /n 0表示不執(zhí)行這個(gè)命令，所以會(huì)比ping出去的時(shí)間更短，也就是即每隔多少時(shí)間最短輸出一個(gè)“■”。當(dāng)然你也可以改為1或2或3等使時(shí)間延長

PS:上面的代碼執(zhí)行太快了，并且第一個(gè)出現(xiàn)的節(jié)奏和后面的不協(xié)調(diào)，我稍微修改了點(diǎn)，如下：
echo.
echo ┌──────────────────────────────────────┐
ping 127.0.0.1 >nul /n 1 & set /p=<nul 
for /L %%i in (1 1 39) do set /p a=■<nul & ping /n 1 127.0.0.1>nul
echo   100%%
echo └──────────────────────────────────────┘
pause

十一、特殊字符的輸入及應(yīng)用

開始 -> 運(yùn)行 -> 輸入cmd -> edit -> ctrl+p（意思是允許輸入特殊字符）-> 按ctrl+a將會(huì)顯示笑臉圖案。

（如果要繼續(xù)輸入特殊字符請?jiān)俅伟碿trl+p，然后ctrl+某個(gè)字母）

以上是特殊字符的輸入方法，選自[英雄]教程，很管用的。也就是用編輯程序edit輸入特殊字符，然后保存為一文本文件，再在windows下打開此文件，復(fù)制其中的特殊符號(hào)即可。

一些簡單的特殊符號(hào)可以在dos命令窗口直接輸入，并用重定向保存為文本文件。
例：
C:>ECHO ^G>temp.txt
“^G”是用Ctrl＋G或Alt＋007輸入(按住Alt后，只能按小鍵盤的數(shù)字)，輸入多個(gè)^G可以產(chǎn)生多聲鳴響。


特殊字符的應(yīng)用也很有意思，這里僅舉一例：退格鍵(輸入方法：開始 -> 運(yùn)行 -> 輸入cmd -> edit -> ctrl+p ->退格鍵)

退格鍵表示刪除左邊的字符，此鍵不能在文檔中正常輸入，但可以通過edit編輯程序錄入并復(fù)制出來。即“”。

利用退格鍵，配合空格覆蓋，可以設(shè)計(jì)閃爍文字效果


例：文字閃爍，可以使用Ctrl+C組合鍵來強(qiáng)行終運(yùn)行
@echo off
:start
set/p=床前明月光<nul
::顯示文字，光標(biāo)停于行尾

ping -n 0 127.0.0.1>nul
::設(shè)置延遲時(shí)間

set /p a=<nul
:: 輸出一些退格符將光標(biāo)置于該行的最左端（退格符的數(shù)量可以自己調(diào)整）。

ping -n 0 127.0.0.1>nul
::設(shè)置延遲時(shí)間

set /p a=                               <nul
::輸出空格將之前輸出的文字覆蓋掉。

set /p a=<nul
::再次輸出退格符將光標(biāo)置于該行的最左端，這里的退格符數(shù)量一定不能比前面的

空格數(shù)少，否則光標(biāo)不能退到最左端。

ping -n 0 127.0.0.1>nul
::設(shè)置延遲時(shí)間

goto start

解說：主要是利用set命令的/p，表示后等號(hào)面的字符都是提示字符，然后在用退格鍵，讓光標(biāo)置于該行的最左端，但是原來的文字還在，然后使用空格作為輸入提示符，所以就會(huì)覆蓋前面的文字，然后再次輸出退格符將光標(biāo)置于該行的最左端，循環(huán)執(zhí)行。如果你把ping命令的次數(shù)改為4，使延遲增長，就能看到光標(biāo)的位置變化了。

例：輸出唐詩一首，每行閃動(dòng)多次
@echo off
setlocal enabledelayedexpansion

set str=床前明月光 疑是地上霜 舉頭望明月 低頭思故鄉(xiāng)
::定義字符串str
for %%i in (%str%) do (
rem 由于str中含有空格，則以空格為分隔符將str中的每一個(gè)部分依次賦給變量%%i。
        set char=%%i
        echo.
        echo.
        for /l %%j in (0,1,5) do (
                set/p=!char:~%%j,1!<nul
  rem 依次取出變量char中的每一個(gè)字符，并顯示。
                ping -n 0 127.0.0.1>nul
  rem 設(shè)置輸出每個(gè)字符的時(shí)間延遲。
        )
call :hero %%i
)
pause>nul
exit

:hero
for /l %%k in (1,1,10) do (
ping /n 0 127.0.0.1>nul
set /p a=<nul
set /p a=                               <nul
set /p a=<nul
ping /n 0 127.0.0.1>nul
set /p a=%1<nul
)
::文字閃動(dòng)
goto :eof

十二、隨機(jī)數(shù)（%random%）的應(yīng)用技巧

%RANDOM% 系統(tǒng)變量 返回 0 到 32767 之間的任意十進(jìn)制數(shù)字。由 Cmd.exe 生成。

2的15次方等于32768，上面的0～32767實(shí)際就是15位二進(jìn)制數(shù)的范圍。

那么，如何獲取100以內(nèi)的隨機(jī)數(shù)呢？很簡單，將%RANDOM%按100進(jìn)行求余運(yùn)算即可，見例子。

例：生成5個(gè)100以內(nèi)的隨機(jī)數(shù)
  @echo off
  setlocal enabledelayedexpansion
  for /L %%i in (1 1 5) do (
     set /a randomNum=!random!%%100
     echo 隨機(jī)數(shù)：!randomNum!
  )
  pause
運(yùn)行結(jié)果：（每次運(yùn)行不一樣）
隨機(jī)數(shù)：91
隨機(jī)數(shù)：67
隨機(jī)數(shù)：58
隨機(jī)數(shù)：26
隨機(jī)數(shù)：20
請按任意鍵繼續(xù). . .

求余數(shù)運(yùn)算set /a randomNum=!random!%%100中的100可以是1～32768之間的任意整數(shù)。

總結(jié)：利用系統(tǒng)變量%random%，求余數(shù)運(yùn)算%%，字符串處理等，可以實(shí)現(xiàn)很多隨機(jī)處理。

通過上面的學(xué)習(xí)，我們知道，%random%可以產(chǎn)生0到32767之間的隨機(jī)數(shù)，但是，如何才能得到一定范圍內(nèi)的隨機(jī)數(shù)呢？ 
我們可以使用通用的算法公式如下： 
　　通用的公式%random%%%(max-min+1)+min來產(chǎn)生[min,max]區(qū)間里的隨機(jī)數(shù)，
注：批處理中求模得用兩個(gè)%%符號(hào)。 
　　比如，我們想獲得4到12之間的隨機(jī)數(shù)，就可以這樣來使用，代碼如下：

@REM 產(chǎn)生10個(gè)[4,12]間的隨機(jī)數(shù) 
@echo off 
REM 啟用延遲環(huán)境變量擴(kuò)展 
setlocal enabledelayedexpansion 
REM 設(shè)置隨機(jī)數(shù)的最小和最大值以及求模用的變量 
set min=4 
set max=12 
set /a mod=!max!-!min!+1

for /l %%i in (1,1,10) do ( 
REM 產(chǎn)生[min,max]之間的隨機(jī)數(shù) 
set /a r=!random!%%!mod!+!min! 
echo. 
echo 隨機(jī)數(shù)%%i：!r!)

詳細(xì)出處參考：http://www.jb51.net/article/36489.htm

思考題目：生成給定位數(shù)的隨機(jī)密碼
解答思路：將26個(gè)英文字母或10數(shù)字以及其它特殊字符組成一個(gè)字符串，隨機(jī)抽取其中的若干字符。

參考答案1：（簡單）
@echo off
call :randomPassword 5 pass1 pass2
echo %pass1% %pass2% 
pause
exit

:randomPassword
::---------生成隨機(jī)密碼
::---------%1為密碼長度，%2及以后為返回變量名稱
::---------for命令最多只能區(qū)分31個(gè)字段
@echo off
set password_len=%1
if not defined password_len goto :eof
if %password_len% lss 1 goto :eof
set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z
set return=
set num=0
:randomPassword1
set /a num+=1
set /a numof=%random%%%26+1
for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
if %num% lss %password_len% goto randomPassword1
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof





參考答案2：（最優(yōu)）
@echo off
call :randomPassword 6 pass1 pass2 pass3
echo %pass1% %pass2% %pass3%
pause
exit

:randomPassword
::---------生成隨機(jī)密碼
::---------%1為密碼長度，%2及以后為返回變量名稱
::---------goto循環(huán)、變量嵌套、命令嵌套
@echo off
if "%1"=="" goto :eof
if %1 lss 1 goto :eof
set password_len=%1
set return=
set wordset=abcdefghijklmnopqrstuvwxyz023456789_
::---------------------------循環(huán)
:randomPassword1
set /a numof=%random%%%36   ::---生成0-35之間的隨即數(shù)
call set return=%return%%%wordset:~%numof%,1%%   ::---在wordset變量中，從的隨即生成的0-35的下一個(gè)取出一個(gè)字符
set /a password_len-=1
if %password_len% gtr 0 goto randomPassword1
::---------------------------循環(huán)
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof



說明：本例涉及到變量嵌套和命令嵌套的應(yīng)用，見后。





十三、變量嵌套 與 命令嵌套

    和其它編程語言相比，dos功能顯得相對簡單，要實(shí)現(xiàn)比較復(fù)雜的功能，需要充分運(yùn)用各種技巧，變量嵌套與命令嵌套就是此類技巧之一。

先復(fù)習(xí)一下前面的“字符串截取”的關(guān)鍵內(nèi)容：

**********************************************
截取功能統(tǒng)一語法格式為：%a:~[m[,n]]%
**********************************************
方括號(hào)表示可選，%為變量標(biāo)識(shí)符，a為變量名，不可少，冒號(hào)用于分隔變量名和說明部分，符號(hào)～可以簡單理解為“偏移”即可，m為偏移量（缺省為0），n為截取長度（缺省為全部）。

百分號(hào)如果需要當(dāng)成單一字符，必須寫成%%

以上是dos變量處理的通用格式，如果其中的m、n為變量，那么這種情況就是變量嵌套了。

比如設(shè)變量word為“abcdefghij”，變量num為“123456789”
%word:~4,1%為e，其中4可以從變量num中取值，即%num:~3,1%，寫成組合形式如下：
%word:~%num:~3,1%,1% 經(jīng)測試這種寫法不能正確執(zhí)行，寫成%word:~(%num:~3,1%),1%同樣不行，那么，怎么實(shí)現(xiàn)這種變量嵌套呢？這就必須結(jié)合命令嵌套。

什么是命令嵌套呢？簡單的說，首先用一條dos命令生成一個(gè)字符串，而這個(gè)字符串是另一條dos命令，用call語句調(diào)用字符串將其執(zhí)行，從而得到最終結(jié)果。

例：用call語句實(shí)現(xiàn)命令嵌套
@echo off
set str1=aaa echo ok bbb
echo 初始字符串：%str1%
echo 生成命令字符串如下：
echo %str1:~4,7%
echo 運(yùn)行命令字符串生成最終結(jié)果為：
call %str1:~4,7%
pause

運(yùn)行顯示：
初始字符串：aaa echo ok bbb
生成命令字符串如下：
echo ok
運(yùn)行命令字符串生成最終結(jié)果為：
ok
請按任意鍵繼續(xù). . .