SQL SERVER2008存儲(chǔ)過程如何加密與解密

SQL SERVER2008存儲(chǔ)過程如何加密與解密，很多新手對(duì)此不是很清楚，為了幫助大家解決這個(gè)難題，下面小編將為大家詳細(xì)講解，有這方面需求的人可以來學(xué)習(xí)下，希望你能有所收獲。

我們?cè)谠O(shè)置數(shù)據(jù)庫存儲(chǔ)過程時(shí)經(jīng)常會(huì)用到加密，如果遇到版本更新需要修改存儲(chǔ)過程時(shí)，如果設(shè)計(jì)數(shù)據(jù)庫時(shí)的存儲(chǔ)過程沒有留存，所以就必須用到存儲(chǔ)過程的解密了，原來自己有個(gè)解密存儲(chǔ)過程在SQL2000下應(yīng)用無問題，后來升級(jí)到SQL2008后不好用了，下在我們就介紹一下在SQL2008下存儲(chǔ)過程的解密方法。

存儲(chǔ)過程的加密

存儲(chǔ)過程加密的方法非常簡(jiǎn)單，我們?cè)谠O(shè)計(jì)存儲(chǔ)過程時(shí)加下WITH ENCRYPTION就可以了。

這樣在數(shù)據(jù)庫里找到存儲(chǔ)過程右鍵點(diǎn)擊存儲(chǔ)過程時(shí)，修改按鈕就是灰色的了，無法查看

接下來我們就來講講SQL2008存儲(chǔ)過程的解密

存儲(chǔ)過程的解密

核心過程sp_DecryptObject

我們解密用到的就是一個(gè)名為sp_DecryptObject的存儲(chǔ)過程，這個(gè)存儲(chǔ)過程我會(huì)在最少貼出其代碼。這里我先講一個(gè)怎么使用這個(gè)解密的方法。

創(chuàng)建解密存儲(chǔ)過程

1.首先打開Microsoft SQL SERVER Managenment Studio，并登陸進(jìn)去

2.然后打開解密的存儲(chǔ)過程，打開后按執(zhí)行鍵我們就在master庫存創(chuàng)建了一個(gè)名為sp_DecryptObject的存儲(chǔ)過程。

注：上面的存儲(chǔ)過程里面有兩個(gè)參數(shù)，第一個(gè)參數(shù)就是我們要解密的存儲(chǔ)過程名稱，第二個(gè)參數(shù)是要解密的字符長(zhǎng)度，默認(rèn)是4000。

使用創(chuàng)建的存儲(chǔ)過程解密

1.首先要新建一個(gè)數(shù)據(jù)庫引擎查詢。點(diǎn)擊文件---新建---數(shù)據(jù)庫引擎查詢。

然后在服務(wù)器名稱這里把我們的服務(wù)器名稱前面加上admin:

然后上面下拉框選擇我們存儲(chǔ)過程所在的數(shù)據(jù)庫，在文本編輯器里面輸入

sp_DecryptObject 存儲(chǔ)過程名，再按執(zhí)行鍵，可以看到下方結(jié)果頁面顯示出來我們的存儲(chǔ)過程文本了。

sp_Decrypttion參數(shù)說明

向上面剛才我們的存儲(chǔ)過程這樣執(zhí)行完從文本里面拷貝出來進(jìn)行修改即可以，但是我們?cè)儆靡粋€(gè)比較長(zhǎng)的存儲(chǔ)過程看一下效果

可以看到上面的存儲(chǔ)過程文本并沒有全部顯示出來，這就是因?yàn)槲覀儎?chuàng)建存儲(chǔ)過程時(shí)第二個(gè)參數(shù)默認(rèn)為4000的問題

下面我們重新修改一下調(diào)用的存儲(chǔ)過程，把第二個(gè)參數(shù)也輸入一個(gè)大點(diǎn)的值

看看效果

我們把第二個(gè)參數(shù)加入了一個(gè)50000的值，可以看到執(zhí)行的結(jié)果里面所有的存儲(chǔ)過程代碼全部顯示出來了。

sp_Decryption源碼

Use master
Go
if object_ID('[sp_DecryptObject]') is not null
    Drop Procedure [sp_DecryptObject]
Go
create procedure sp_DecryptObject
(
    @Object sysname,    --要解密的對(duì)象名：函數(shù)，存儲(chǔ)過程，視圖或觸發(fā)器
    @MaxLength int=4000 --評(píng)估內(nèi)容的長(zhǎng)度
)
as
set nocount on
/* 1. 解密 */
 
if not exists(select 1 from sys.objects a where a.object_id=object_id(@Object) And a.type in('P','V','TR','FN','IF','TF'))
begin
    --SQL Server 2008
    raiserror 50001 N'無效的對(duì)象！要解密的對(duì)象必須是函數(shù)，存儲(chǔ)過程，視圖或觸發(fā)器。'

    --SQL Server 2012
    --throw 50001, N'無效的對(duì)象！要解密的對(duì)象必須是函數(shù)，存儲(chǔ)過程，視圖或觸發(fā)器。',1   
    return
end
 
if exists(select 1 from sys.sql_modules a where a.object_id=object_id(@Object) and a.definition is not null)
begin
    --SQL Server 2008
    raiserror 50001 N'對(duì)象沒有加密！'

    --SQL Server 2012
    --throw 50001, N'無效的對(duì)象！要解密的對(duì)象必須是函數(shù)，存儲(chǔ)過程，視圖或觸發(fā)器。',1
    return
end
 
declare  @sql nvarchar(max)                --解密出來的SQL語句
        ,@imageval nvarchar(max)        --加密字符串
        ,@tmpStr nvarchar(max)            --臨時(shí)SQL語句
        ,@tmpStr_imageval nvarchar(max) --臨時(shí)SQL語句(加密后)
        ,@type char(2)                    --對(duì)象類型('P','V','TR','FN','IF','TF')
        ,@objectID int                    --對(duì)象ID
        ,@i int                            --While循環(huán)使用
        ,@Oject1 nvarchar(1000)
 
set @objectID=object_id(@Object)
set @type=(select a.type from sys.objects a where a.object_id=@objectID)
 
declare @Space4000 nchar(4000)
set @Space4000=replicate('-',4000)
 
/*
@tmpStr 會(huì)構(gòu)造下面的SQL語句
-------------------------------------------------------------------------------
alter trigger Tr_Name on Table_Name with encryption for update as return /**/
alter proc Proc_Name with encryption  as select 1 as col /**/
alter view View_Name with encryption as select 1 as col /**/
alter function Fn_Name() returns int with encryption as begin return(0) end/**/
*/
set @Oject1=quotename(object_schema_name(@objectID))+'.'+quotename(@Object)
set @tmpStr=
        case     
            when @type ='P ' then N'Alter Procedure '+@Oject1+' with encryption as select 1 as column1 '
            when @type ='V ' then N'Alter View '+@Oject1+' with encryption as select 1 as column1 '
            when @type ='FN' then N'Alter Function '+@Oject1+'() returns int with encryption as begin return(0) end '
            when @type ='IF' then N'Alter Function '+@Oject1+'() returns table with encryption as return(Select a.name from sys.types a) '
            when @type ='TF' then N'Alter Function '+@Oject1+'() returns @t table(name nvarchar(50)) with encryption as begin return end '
            else 'Alter Trigger '+@Oject1+'on '+quotename(object_schema_name(@objectID))+'.'+(select Top(1) quotename(object_name(parent_id)) from sys.triggers a where a.object_id=@objectID)+' with encryption for update as return '
        end        
 
    
set @tmpStr=@tmpStr+'/*'+@Space4000
set @i=0
while @i < (ceiling(@MaxLength*1.0/4000)-1)
begin
    set @tmpStr=@tmpStr+ @Space4000
    Set @i=@i+1
end
set @tmpStr=@tmpStr+'*/'
 
------------
set @imageval =(select top(1) a.imageval from sys.sysobjvalues a where a.objid=@objectID and a.valclass=1)
 
begin tran
exec(@tmpStr)
set @tmpStr_imageval =(select top(1) a.imageval from sys.sysobjvalues a where a.objid=@objectID and a.valclass=1)
 
rollback tran
 
-------------
set @tmpStr=stuff(@tmpStr,1,5,'create')
set @sql=''
set @i=1
while @i<= (datalength(@imageval)/2)
begin
    set @sql=@sql+isnull(nchar(unicode(substring(@tmpStr,@i,1)) ^ unicode(substring(@tmpStr_imageval,@i,1))^unicode(substring(@imageval,@i,1)) ),'')
    Set @i+=1
end
 
/* 2. 列印 */
declare @patindex int    
while @sql>''
begin
    set @patindex=patindex('%'+char(13)+char(10)+'%',@sql)
    if @patindex >0
    begin
        print substring(@sql,1,@patindex-1)
        set @sql=stuff(@sql,1,@patindex+1,'')
    end    
    else
    begin
        set @patindex=patindex('%'+char(13)+'%',@sql)
        if @patindex >0
        begin
            print substring(@sql,1,@patindex-1)
            set @sql=stuff(@sql,1,@patindex,'')
        end
        else
        begin
            set @patindex=patindex('%'+char(10)+'%',@sql)
            if @patindex >0
            begin
                print substring(@sql,1,@patindex-1)
                set @sql=stuff(@sql,1,@patindex,'')
            end        
            else
            begin
                print @sql
                set @sql=''
            end    
        end        
    end       
end
 
Go
exec sp_ms_marksystemobject 'sp_DecryptObject' --標(biāo)識(shí)為系統(tǒng)對(duì)象
go

看完上述內(nèi)容是否對(duì)您有幫助呢？如果還想對(duì)相關(guān)知識(shí)有進(jìn)一步的了解或閱讀更多相關(guān)文章，請(qǐng)關(guān)注億速云行業(yè)資訊頻道，感謝您對(duì)億速云的支持。