Solidity函數(shù)類型是什么

本篇內(nèi)容介紹了“Solidity函數(shù)類型是什么”的有關(guān)知識(shí)，在實(shí)際案例的操作過程中，不少人都會(huì)遇到這樣的困境，接下來就讓小編帶領(lǐng)大家學(xué)習(xí)一下如何處理這些情況吧！希望大家仔細(xì)閱讀，能夠?qū)W有所成！

函數(shù)類型（Function Types）

函數(shù)也是一種類型，且屬于值類型。 可以將一個(gè)函數(shù)賦值給一個(gè)函數(shù)類型的變量。還可以將一個(gè)函數(shù)作為參數(shù)進(jìn)行傳遞。也可以在函數(shù)調(diào)用中返回一個(gè)函數(shù)。 函數(shù)類型有兩類:內(nèi)部(internal)和外部(external)函數(shù)

內(nèi)部(internal)函數(shù)只能在當(dāng)前合約內(nèi)被調(diào)用（在當(dāng)前的代碼塊內(nèi)，包括內(nèi)部庫(kù)函數(shù)，和繼承的函數(shù)中）。 外部(external)函數(shù)由地址和函數(shù)方法簽名兩部分組成，可作為外部函數(shù)調(diào)用的參數(shù)，或返回值。

函數(shù)類型定義如下：

function (<parameter types>) {internal|external} [pure|constant|view|payable] [returns (<return types>)]

如果函數(shù)不需要返回，則省去returns (<return types>) 函數(shù)類型默認(rèn)是internal， 因此internal可以省去。但以此相反，合約中函數(shù)本身默認(rèn)是public的， 僅僅是當(dāng)作類型名使用時(shí)默認(rèn)是internal的。

有兩個(gè)方式訪問函數(shù)，一種是直接用函數(shù)名f, 一種是this.f， 前者用于內(nèi)部函數(shù)，后者用于外部函數(shù)。

如果一個(gè)函數(shù)變量沒有初始化，直接調(diào)用它將會(huì)產(chǎn)生異常。如果delete了一個(gè)函數(shù)后調(diào)用，也會(huì)發(fā)生同樣的異常。

如果外部函數(shù)類型在Solidity的上下文環(huán)境以外的地方使用，他們會(huì)被視為function類型。它會(huì)編碼為20字節(jié)的函數(shù)所在地址，和在它之前的4字節(jié)的函數(shù)方法簽名一起作為bytes24類型。 合約中的public的函數(shù)，可以使用internal和external兩種方式來調(diào)用。 internal訪問形式為f, external訪問形式為this.f

成員: 屬性 selector

public (或 external) 函數(shù)有一個(gè)特殊的成員selector, 它對(duì)應(yīng)一個(gè)ABI 函數(shù)選擇器。 ```js pragma solidity ^0.4.16;

contract Selector {
function f() public view returns (bytes4) {
    return this.f.selector;
}
}
```

下面的代碼顯示內(nèi)部（internal）函數(shù)類型的使用：

pragma solidity ^0.4.16;

library ArrayUtils {
  // internal functions can be used in internal library functions because
  // they will be part of the same code context
  function map(uint[] memory self, function (uint) pure returns (uint) f)
    internal
    pure
    returns (uint[] memory r)
  {
    r = new uint[](self.length);
    for (uint i = 0; i < self.length; i++) {
      r[i] = f(self[i]);
    }
  }
  function reduce(
    uint[] memory self,
    function (uint, uint) pure returns (uint) f
  )
    internal
    pure
    returns (uint r)
  {
    r = self[0];
    for (uint i = 1; i < self.length; i++) {
      r = f(r, self[i]);
    }
  }
  function range(uint length) internal pure returns (uint[] memory r) {
    r = new uint[](length);
    for (uint i = 0; i < r.length; i++) {
      r[i] = i;
    }
  }
}

contract Pyramid {
  using ArrayUtils for *;
  function pyramid(uint l) public pure returns (uint) {
    return ArrayUtils.range(l).map(square).reduce(sum);
  }
  function square(uint x) internal pure returns (uint) {
    return x * x;
  }
  function sum(uint x, uint y) internal pure returns (uint) {
    return x + y;
  }
}

下面的代碼顯示外部（external）函數(shù)類型的使用：

pragma solidity ^0.4.11;

contract Oracle {
  struct Request {
    bytes data;
    function(bytes memory) external callback;
  }
  Request[] requests;
  event NewRequest(uint);
  function query(bytes data, function(bytes memory) external callback) public {
    requests.push(Request(data, callback));
    NewRequest(requests.length - 1);
  }
  function reply(uint requestID, bytes response) public {
    // Here goes the check that the reply comes from a trusted source
    requests[requestID].callback(response);
  }
}

contract OracleUser {
  Oracle constant oracle = Oracle(0x1234567); // known contract
  function buySomething() {
    oracle.query("USD", this.oracleResponse);
  }
  function oracleResponse(bytes response) public {
    require(msg.sender == address(oracle));
    // Use the data
  }
}

函數(shù)可見性分析

• public - 任意訪問

• private - 僅當(dāng)前合約內(nèi)

• internal - 僅當(dāng)前合約及所繼承的合約

• external - 僅外部訪問（在內(nèi)部也只能用外部訪問方式訪問）

“Solidity函數(shù)類型是什么”的內(nèi)容就介紹到這里了，感謝大家的閱讀。如果想了解更多行業(yè)相關(guān)的知識(shí)可以關(guān)注億速云網(wǎng)站，小編將為大家輸出更多高質(zhì)量的實(shí)用文章！