批處理如何實(shí)現(xiàn)使用FLASHGET檢查Mcafee SuperDat更新

這篇文章主要介紹了批處理如何實(shí)現(xiàn)使用FLASHGET檢查Mcafee SuperDat更新，具有一定借鑒價(jià)值，感興趣的朋友可以參考下，希望大家閱讀完這篇文章之后大有收獲，下面讓小編帶著大家一起了解一下。

因做了一個(gè)腳本，使用Mcafee SuperDat進(jìn)行查毒（http://blog.csdn.net/scz123/archive/2006/11/02/1362566.aspx），但病毒碼更新時(shí)，都要到網(wǎng)站上去手動(dòng)下載，固建此腳本，使用FLASHGET下載后的的病毒檢查功能來運(yùn)行，以達(dá)到讓自動(dòng)檢查并下載Mcafee SuperDat更新的功能。

代碼如下:

@echo off 
echo. 
echo ================================================== 
echo FLASHGET下載檢測腳本，用來自動(dòng)更新MCAFEE SUPERDAT 
echo created by scz 20061102 
echo ================================================== 
rem 請(qǐng)使用FLASHGET的病毒檢測功能，指定為該腳本 
rem 主要使用FLASHGET下載更新頁面時(shí)使用 
rem 讓FLASHGET1.5以上版本定時(shí)下載更新頁面:"E:\Program Files\FlashGet\flashget.exe" http://www.mcafee.com/apps/downloads/security_updates/superdat.asp?region=cn&segment=enterprise f:\bak\checkMcafee 
rem 配只了病毒檢測的flashget,下載完后就會(huì)運(yùn)行此腳本,然后自動(dòng)更新SupperDat 
rem 然后定期重新下載頁面即可 

rem 下載到文件的路徑、文件名和擴(kuò)展名 
set filepath=%~dp1 
set filename=%~n1 
set fileExt=%~x1 

rem FLASHGET路徑 
set FLASHGET="E:\Program Files\FlashGet\flashget.exe" 

rem SuperDat存放路徑 
set datPath=f:\bak\update\ 

rem 檢查的asp頁面存放路徑 
set aspPath=f:\bak\checkMcafee\ 

rem 字符串比較 
echo. 
echo 檢查下載的文件格式與位置... 
(echo -%filepath%- | find /i "-%datPath%-" >nul) && (echo -%filename%- | find /i "-sdat" >nul) && (echo -%fileExt%- | find /i "-.exe-" >nul) && goto checkdat 
(echo -%filepath%- | find /i "-%aspPath%-" >nul) && (echo -%filename%%fileExt%- | find /i "-superdat.asp-" >nul) && goto checkasp 

echo 下載到文件：%filepath%%filename%%fileExt%，不需要處理 
goto end 

:checkdat 
echo. 
echo 下載到SuperDat: %filename%%fileExt%,處理中... 
cd /d %datPath% 
ren %filename%%fileExt% McAfee.%filename%%fileExt% 
echo 刪除老版SuperDat... 
for /f "skip=1" %%i in ('dir mcafee*.exe /tc /o-d /b 2^>nul') do (del %%i) 
echo 通知釋放MCAFEE SUPERDAT... 
start "" McAfee.%filename%%fileExt% /e c:\mcafee 
echo SuperDat處理完畢. 
goto end 

:checkasp 
echo. 
echo 下載到superdat.asp... 
set url= 
set sdatname= 
cd /d f:\bak\checkMcafee 
echo 分析superdat.asp... 
for /f "tokens=3,4* delims=<>=" %%i in ('type superdat.asp ^| find "simplified/sdat"') do (set url=%%i & set sdatname=%%j) 
set ver0=%sdatname:sdat=% 
set ver1=%ver0:.exe=% 
echo 分析結(jié)果：SUPPERDAT版本號(hào)為%ver1% 

cd /d %datPath% 
if exist %sdatname% ren %sdatname% McAfee.%sdatname% 
if exist mcafee.%sdatname% (echo 已存在最新版本 &goto end) else (echo 該版本未下載，通知FLASHGET下載 &start "" %FLASHGET% %url% %datPath%) 
goto end 

:end 
echo. 
pause  

感謝你能夠認(rèn)真閱讀完這篇文章，希望小編分享的“批處理如何實(shí)現(xiàn)使用FLASHGET檢查Mcafee SuperDat更新”這篇文章對(duì)大家有幫助，同時(shí)也希望大家多多支持億速云，關(guān)注億速云行業(yè)資訊頻道，更多相關(guān)知識(shí)等著你來學(xué)習(xí)!