怎么用bat腳本實(shí)現(xiàn)自動(dòng)關(guān)機(jī)

這篇文章主要介紹“怎么用bat腳本實(shí)現(xiàn)自動(dòng)關(guān)機(jī)”，在日常操作中，相信很多人在怎么用bat腳本實(shí)現(xiàn)自動(dòng)關(guān)機(jī)問(wèn)題上存在疑惑，小編查閱了各式資料，整理出簡(jiǎn)單好用的操作方法，希望對(duì)大家解答”怎么用bat腳本實(shí)現(xiàn)自動(dòng)關(guān)機(jī)”的疑惑有所幫助！接下來(lái)，請(qǐng)跟著小編一起來(lái)學(xué)習(xí)吧！

一般情況下我們都是使用shutdown來(lái)實(shí)現(xiàn)關(guān)機(jī)與重啟

用法: shutdown [/i | /l | /s | /r | /a | /p | /h | /e] [/f]
[/m \\computer][/t xxx][/d [p:]xx:yy [/c "comment"]]

沒(méi)有參數(shù) 顯示幫助。這與鍵入 /? 是一樣的
/? 顯示幫助。這與不鍵入任何選項(xiàng)是一樣的
/i 顯示圖形用戶界面(GUI)。
這必須是第一個(gè)選項(xiàng)
/l 注銷。這不能與 /m 或 /d 選項(xiàng)一起使用
/s 關(guān)閉計(jì)算機(jī)
/r 關(guān)閉并重啟動(dòng)計(jì)算機(jī)
/a 放棄系統(tǒng)關(guān)閉。
這只能在超時(shí)過(guò)程中使用
/p 關(guān)閉本地計(jì)算機(jī)，沒(méi)有超時(shí)或警告。
這只能與 /d 選項(xiàng)一起使用
/h 休眠本地計(jì)算機(jī)。
這只能與 /f 選項(xiàng)一起使用
/e 將計(jì)算機(jī)的意外關(guān)閉原因記入文檔
/m \\computer 指定目標(biāo)計(jì)算機(jī)
/t xxx 設(shè)置關(guān)閉前的超時(shí)為 xxx 秒。
有效范圍是 0-600，默認(rèn)為 30
/c "comment" 重啟動(dòng)或關(guān)閉的原因的注釋。
最大允許 127 個(gè)字符
/f 強(qiáng)制正在運(yùn)行的應(yīng)用程序關(guān)閉而不事先警告用戶
/d [p:]xx:yy 提供重啟動(dòng)或關(guān)閉的原因
p 表明重啟動(dòng)或關(guān)閉是計(jì)劃內(nèi)的
xx 是主要原因號(hào)(小于 256 的正整數(shù))
yy 是次要原因號(hào)(小于 65536 的正整數(shù))

重啟
shutdown /r /f

關(guān)機(jī)
shutdown /s /f

先來(lái)個(gè)簡(jiǎn)單功能版本的

代碼如下:

@echo off
mode con lines=25
title 定時(shí)關(guān)機(jī)
color 1f
cls
echo.
echo.
echo.
echo.
echo              時(shí)間使用24小時(shí)制(如2:15、12:00)，可以輸入多個(gè)時(shí)間點(diǎn)
echo.
echo                           多個(gè)時(shí)間點(diǎn)用空格分隔
echo.
echo.
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
echo.
set times=
set /p times=                     請(qǐng)輸入關(guān)機(jī)時(shí)間：
:: 以下語(yǔ)句實(shí)現(xiàn)每個(gè)星期的每一天指定時(shí)間關(guān)機(jī)
:: 如果要換成每個(gè)月的某幾天，請(qǐng)改字母為數(shù)字，并用逗號(hào)分隔
:: 以下代碼沒(méi)有錯(cuò)誤檢測(cè)語(yǔ)句，輸入時(shí)間的時(shí)候務(wù)必按照指定格式輸入
:: 可以用在CMD窗口用at命令來(lái)查看計(jì)劃任務(wù)
if not "%times%"=="" for %%i in (%times%) do (
    at %%i /every:M,T,W,Th,F,S,Su shutdown -s
)

下面是多功能版的，適合學(xué)習(xí)bat的朋友

代碼如下:

@ECHO off
TITLE 自動(dòng)關(guān)機(jī)程序 作者:廖曉青
:start
CLS
COLOR 1f
rem 使用COLOR命令對(duì)控制臺(tái)輸出顏色進(jìn)行更改
MODE con: COLS=41 LINES=18
rem MODE語(yǔ)句為設(shè)定窗體的寬和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%點(diǎn)%tm2%分%tm3%秒
ECHO =========================================
ECHO 請(qǐng)選擇要進(jìn)行的操作，然后按回車
ECHO ───────────────
ECHO.
ECHO 1. 定時(shí)關(guān)機(jī)
ECHO 2. 倒計(jì)時(shí)關(guān)機(jī)
ECHO 3. 刪除定時(shí)關(guān)機(jī)任務(wù)
ECHO 4. 查看任務(wù)狀態(tài)
ECHO 5. 刷新當(dāng)前時(shí)間
ECHO 6. 重新啟動(dòng)
ECHO 7. 鎖定計(jì)算機(jī)
ECHO 8. 注銷
ECHO 9. 退出
ECHO.

:cho
SET Choice=
SET /P Choice=選擇:
rem 設(shè)定變量"Choice"為用戶輸入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果輸入大于1位,取第1位,比如輸入132,則返回值為1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 為避免出現(xiàn)返回值為空或含空格而導(dǎo)致程序異常,需在變量外另加雙引號(hào)
rem 注意,IF語(yǔ)句需要雙等于號(hào)
rem 如果輸入的字符不是以上數(shù)字,將返回重新輸入
ECHO 選擇無(wú)效，請(qǐng)重新輸入
ECHO.
GOTO cho

:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否設(shè)定為每天執(zhí)行關(guān)機(jī)命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour

:yes
ECHO 請(qǐng)指定24小時(shí)制式時(shí)間,格式為 小時(shí):分鐘
SET shutdowntime=
SET /p shutdowntime=輸入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 設(shè)定為每周的星期一至星期日,即為每天
IF NOT errorlevel 1 GOTO ok
rem 如果輸入正確,就執(zhí)行ok段的語(yǔ)句
ECHO %shutdowntime% 不是標(biāo)準(zhǔn)的時(shí)間格式,請(qǐng)重新輸入
ECHO.
GOTO yes

:no
ECHO 請(qǐng)指定24小時(shí)制式時(shí)間,格式為 小時(shí):分鐘
SET shutdowntime=
SET /p shutdowntime=輸入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是標(biāo)準(zhǔn)的時(shí)間格式,請(qǐng)重新輸入
ECHO.
GOTO no

:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%時(shí)%am%分
) ELSE (
SET HM=%bh%時(shí)%bm%分)
rem 如果輸入h:mm則HM=h時(shí)mm分,否則HM=hh時(shí)mm分
IF /I "%ask%"=="y" ECHO 系統(tǒng)將于每天的%HM%關(guān)閉
IF /I "%ask%"=="n" ECHO 系統(tǒng)將于%HM%關(guān)閉
ECHO 設(shè)定完畢! 按任意鍵繼續(xù)...
PAUSE >nul
GOTO start

:outtime
CLS
ECHO.
ECHO 請(qǐng)輸入倒計(jì)時(shí)秒數(shù)
ECHO ────────
ECHO (設(shè)定后要取消,單擊"確定"后按Ctrl+C鍵兩次)
SET timed=
SET /p timed=輸入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是無(wú)效的關(guān)機(jī)時(shí)間,請(qǐng)重新輸入
ECHO.
GOTO outtime

:delAt
cls
echo.
at /del /y
echo 定時(shí)關(guān)機(jī)任務(wù)已取消,按任意鍵繼續(xù)...
pause >nul
GOTO start

:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意鍵繼續(xù)...
PAUSE >nul
GOTO start

:restart
shutdown -r -t 0

:lock
rundll32.exe user32.dll,LockWorkStation
goto start

:logoff
logoff

:end
exit

到此，關(guān)于“怎么用bat腳本實(shí)現(xiàn)自動(dòng)關(guān)機(jī)”的學(xué)習(xí)就結(jié)束了，希望能夠解決大家的疑惑。理論與實(shí)踐的搭配能更好的幫助大家學(xué)習(xí)，快去試試吧！若想繼續(xù)學(xué)習(xí)更多相關(guān)知識(shí)，請(qǐng)繼續(xù)關(guān)注億速云網(wǎng)站，小編會(huì)繼續(xù)努力為大家?guī)?lái)更多實(shí)用的文章！