CMD下如何配置網(wǎng)絡安全

這篇文章主要為大家展示了“CMD下如何配置網(wǎng)絡安全”，內(nèi)容簡而易懂，條理清晰，希望能夠幫助大家解決疑惑，下面讓小編帶領(lǐng)大家一起研究并學習一下“CMD下如何配置網(wǎng)絡安全”這篇文章吧。

自帶的關(guān)于網(wǎng)絡的命令行工具很多，比如大家熟悉的ping,tracert,ipconfig,telnet,ftp,tftp,netstat，還有不太熟悉的nbtstat,pathping,nslookup,finger,route,netsh......
這些命令又可分成三類：網(wǎng)絡檢測（如ping）、網(wǎng)絡連接（如telnet）和網(wǎng)絡配置（如netsh）。前面兩種相對簡單，本文只介紹兩個網(wǎng)絡配置工具。

netsh
在遠程shell中使用netsh首先要解決一個交互方式的問題。前面說過，很多shell不能再次重定向輸出輸出，所以不能在這種環(huán)境下交互地使用ftp等命令行工具。解決的辦法是，一般交互式的工具都允許使用腳本（或者叫應答文件）。比如ftp -s:filename。netsh也是這樣：netsh -f filename。

netsh命令的功能非常多，可以配置IAS、DHCP、RAS、WINS、NAT服務器，TCP/IP協(xié)議，IPX協(xié)議，路由等。我們不是管理員，一般沒必要了解這么多，只需用netsh來了解目標主機的網(wǎng)絡配置信息。

1，TCP/IP配置

echo interface ip >s
echo show config >>s
netsh -f s
del s

由此你可以了解該主機有多個網(wǎng)卡和IP，是否是動態(tài)分配IP(DHCP)，內(nèi)網(wǎng)IP是多少（如果有的話）。
這個命令和ipconfig /all差不多。

注意，以下命令需要目標主機啟動remoteaccess服務。如果它被禁用，請先通過導入注冊表解禁，然后
net start remoteaccess

2，ARP

echo interface ip >s
echo show ipnet >>s
netsh -f s
del s

這個比arp -a命令多一點信息。

3，TCP/UDP連接

echo interface ip >s
echo show tcpconn >>s
echo show udpconn >>s
netsh -f s
del s

這組命令和netstat -an一樣。

4，網(wǎng)卡信息
如果netsh命令都有其他命令可代替，那它還有什么存在的必要呢？下面這個就找不到代替的了。

echo interface ip >s
echo show interface >>s
netsh -f s
del s

netsh的其他功能，比如修改IP，一般沒有必要使用（萬一改了IP后連不上，就"叫天不應叫地不靈"了），所以全部略過。

IPSec
首先需要指出的是，IPSec和TCP/IP篩選是不同的東西，大家不要混淆了。TCP/IP篩選的功能十分有限，遠不如IPSec靈活和強大。下面就說說如何在命令行下控制IPSec。

XP系統(tǒng)用ipseccmd，2000下用ipsecpol。遺憾的是，它們都不是系統(tǒng)自帶的。ipseccmd在xp系統(tǒng)安裝盤的SUPPORT\TOOLS\SUPPORT.CAB中，ipsecpol在2000 Resource Kit里。而且，要使用ipsecpol還必須帶上另外兩個文件：ipsecutil.dll和text2pol.dll。三個文件一共119KB。

IPSec可以通過組策略來控制，但我找遍MSDN，也沒有找到相應的安全模板的語法。已經(jīng)配置好的IPSec策略也不能被導出為模板。所以，組策略這條路走不通。IPSec的設(shè)置保存在注冊表中(HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\IPSec\Policy\Local)，理論上可以通過修改注冊表來配置IPSec。但很多信息以二進制形式存放，讀取和修改都很困難。相比之下，上傳命令行工具更方便。

關(guān)于ipsecpol和ipseccmd的資料，網(wǎng)上可以找到很多，因此本文就不細說了，只是列舉一些實用的例子。
在設(shè)置IPSec策略方面，ipseccmd命令的語法和ipsecpol幾乎完全一樣，所以只以ipsecpol為例：

1，防御rpc-dcom攻擊

ipsecpol -p myfirewall -r rpc-dcom -f *+0:135:tcp *+0:135:udp *+0:137:udp *+0:138:udp *+0:139:tcp *+0:445:tcp *+0:445:udp -n BLOCK -w reg -x

這條命令關(guān)閉了本地主機的TCP135,139,445和udp135,137,138,445端口。
具體含義如下：
-p myfirewall 指定策略名為myfirewall
-r rpc-dcom 指定規(guī)則名為rpc-dcom
-f ...... 建立7個篩選器。*表示任何地址(源)；0表示本機地址(目標)；+表示鏡像(雙向)篩選。詳細語法見ipsecpol -?
-n BLOCK 指定篩選操作是"阻塞"。注意，BLOCK必須是大寫。
-w reg 將配置寫入注冊表，重啟后仍有效。
-x 立刻激活該策略。

2，防止被ping

ipsecpol -p myfirewall -r antiping -f *+0::icmp -n BLOCK -w reg -x

如果名為myfirewall的策略已存在，則antiping規(guī)則將添加至其中。
注意，該規(guī)則同時也阻止了該主機ping別人。

3，對后門進行IP限制
假設(shè)你在某主機上安裝了DameWare Mini Remote Control。為了保護它不被別人暴破密碼或溢出，應該限制對其服務端口6129的訪問。

ipsecpol -p myfw -r dwmrc_block_all -f *+0:6129:tcp -n BLOCK -w reg
ipsecpol -p myfw -r dwmrc_pass_me -f 123.45.67.89+0:6129:tcp -n PASS -w reg -x

這樣就只有123.45.67.89可以訪問該主機的6129端口了。
如果你是動態(tài)IP，應該根據(jù)IP分配的范圍設(shè)置規(guī)則。比如：

ipsecpol -p myfw -r dwmrc_block_all -f *+0:6129:tcp -n BLOCK -w reg
ipsecpol -p myfw -r dwmrc_pass_me -f 123.45.67.*+0:6129:tcp -n PASS -w reg -x

這樣就允許123.45.67.1至123.45.67.254的IP訪問6129端口。

在寫規(guī)則的時候，應該特別小心，不要把自己也阻塞了。如果你不確定某個規(guī)則的效果是否和預想的一樣，可以先用計劃任務"留下后路"。例如：

c:\>net start schedule
Task Scheduler 服務正在啟動 ..
Task Scheduler 服務已經(jīng)啟動成功。

c:\>time /t
12:34

c:\>at 12:39 ipsecpol -p myfw -y -w reg
新加了一項作業(yè)，其作業(yè) ID = 1

然后，你有5分鐘時間設(shè)置一個myfw策略并測試它。5分鐘后計劃任務將停止該策略。
如果測試結(jié)果不理想，就刪除該策略。

c:\>ipsecpol -p myfw -o -w reg

注意，刪除策略前必須先確保它已停止。不停止它的話，即使刪除也會在一段時間內(nèi)繼續(xù)生效。持續(xù)時間取決于策略的刷新時間，默認是180分鐘。

如果測試通過，那么就啟用它。

c:\>ipsecpol -p myfw -x -w reg

最后說一下查看IPSec策略的辦法。
對于XP很簡單，一條命令搞定--ipseccmd show filters
而ipsecpol沒有查詢的功能。需要再用一個命令行工具netdiag。它位于2000系統(tǒng)安裝盤的SUPPORT\TOOLS\SUPPORT.CAB中。（已經(jīng)上傳了三個文件，也就不在乎多一個了。^_^）

netdiag需要RemoteRegistry服務的支持。所以先啟動該服務：

net start remoteregistry

不啟動RemoteRegistry就會得到一個錯誤：

[FATAL] Failed to get system information of this machine.

netdiag這個工具功能十分強大，與網(wǎng)絡有關(guān)的信息都可以獲取！不過，輸出的信息有時過于詳細，超過命令行控制臺cmd.exe的輸出緩存，而不是每個遠程cmd shell都可以用more命令來分頁的。

查看ipsec策略的命令是：
netdiag /debug /test:ipsec

然后是一長串輸出信息。IPSec策略位于最后。


軟件安裝
一個軟件/工具的安裝過程，一般來說只是做兩件事：拷貝文件到特定目錄和修改注冊表。只要搞清楚具體的內(nèi)容，那么就可以自己在命令行下實現(xiàn)了。（不考慮安裝后需要注冊激活等情況）

WinPcap是個很常用的工具，但必須在窗口界面下安裝。在網(wǎng)上也可以找到不用GUI的版本（但還是有版權(quán)頁），其實我們完全可以自己做一個。

以WinPcap 3.0a 為例。通過比較安裝前后的文件系統(tǒng)和注冊表快照，很容易了解整個安裝過程。
除去反安裝的部分，關(guān)鍵的文件有三個：wpcap.dll，packet.dll和npf.sys。前面兩個文件位于system32目錄下，第三個在system32\drivers下。而注冊表的變化是增加了一個系統(tǒng)服務NPF。注意，是系統(tǒng)服務（即驅(qū)動）不是Win32服務。

作為系統(tǒng)服務，不但要在HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services下增加主鍵，在HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Enum\Root下也增加主鍵。而后者默認只有SYSTEM身份才可以修改。幸運的是，并不需要手動添加它，winpcap被調(diào)用時會自動搞定。甚至完全不用手動修改注冊表，所有的事winpcap都會自己完成，只需要將三個文件復制到合適的位置就行了。

作為范例，還是演示一下如何修改注冊表：利用前面說過的inf文件來實現(xiàn)。

[Version]
Signature="$WINDOWS NT$"
[DefaultInstall.Services]
AddService=NPF,,winpcap_svr
[winpcap_svr]
DisplayName=Netgroup Packet Filter
ServiceType=0x1
StartType=3
ErrorControl=1
ServiceBinary=%12%\npf.sys

將上面這些內(nèi)容保存為_wpcap_.inf文件。
再寫一個批處理_wpcap_.bat：

rundll32.exe setupapi,InstallHinfSection DefaultInstall 128 %CD%\_wpcap_.inf
del _wpcap_.inf
if /i %CD%==%SYSTEMROOT%\system32 goto COPYDRV
copy packet.dll %SYSTEMROOT%\system32\
copy wpcap.dll %SYSTEMROOT%\system32\
del packet.dll
del wpcap.dll
:COPYDRV
if /i %CD%==%SYSTEMROOT%\system32\drivers goto END
copy npf.sys %SYSTEMROOT%\system32\drivers\
del npf.sys
:END
del %0

然后用winrar將所有文件（5個）打包為自解壓的exe，并將『高級自解壓選項』->『解壓后運行』設(shè)置為_wpcap_.bat，命令行的winpcap安裝包就制作完成了。

注意，批處理最后一行沒有回車符。否則會因為正在運行而無法刪除自己。

所有的軟件安裝，基本上可以套用這個思路。但也有例外的，那就是系統(tǒng)補丁的安裝。
由于系統(tǒng)補丁有可能要替換正在被執(zhí)行或訪問的文件，所以用copy命令是不行的。
幸好，Windows補丁包支持命令行安裝。
比如：

KB824146.exe -n -z -q

-n 不保留備份
-z 不重起
-q 安靜模式

如果有一堆補丁要打，那么用RAR打包成自解壓文件，外加一個批處理。

for %%f in (KB??????.exe) do %%f -n -z -q
for %%f in (KB??????.exe) do del %%f
del %0


Windows腳本
很多事用腳本來做是很簡潔的。下面給出幾個常用腳本的echo版。

1，顯示系統(tǒng)版本

@echo for each ps in getobject _ >ps.vbs
@echo ("winmgmts:\\.\root\cimv2:win32_operatingsystem").instances_ >>ps.vbs
@echo wscript.echo ps.caption^&" "^&ps.version:next >>ps.vbs
cscript //nologo ps.vbs & del ps.vbs

2，列舉進程

@echo for each ps in getobject _ >ps.vbs
@echo ("winmgmts:\\.\root\cimv2:win32_process").instances_ >>ps.vbs
@echo wscript.echo ps.handle^&vbtab^&ps.name^&vbtab^&ps.executablepath:next >>ps.vbs
cscript //nologo ps.vbs & del ps.vbs

3，終止進程

@echo for each ps in getobject _ >pk.vbs
@echo ("winmgmts:\\.\root\cimv2:win32_process").instances_ >>pk.vbs
@echo if ps.handle=wscript.arguments(0) then wscript.echo ps.terminate:end if:next >>pk.vbs

要終止PID為123的進程，使用如下語法：
cscript pk.vbs 123

如果顯示一個0，表示終止成功。

然后：
del pk.vbs

4，重啟系統(tǒng)

@echo for each os in getobject _ >rb.vbs
@echo ("winmgmts:{(shutdown)}!\\.\root\cimv2:win32_operatingsystem").instances_ >>rb.vbs
@echo os.win32shutdown(2):next >>rb.vbs & cscript //nologo rb.vbs & del rb.vbs

5，列舉自啟動的服務

@echo for each sc in getobject("winmgmts:\\.\root\cimv2:win32_service").instances_ >sc.vbs
@echo if sc.startmode="Auto" then wscript.echo sc.name^&" - "^&sc.pathname >>sc.vbs
@echo next >>sc.vbs & cscript //nologo sc.vbs & del sc.vbs

6，列舉正在運行的服務

@echo for each sc in getobject("winmgmts:\\.\root\cimv2:win32_service").instances_ >sc.vbs
@echo if sc.state="Running" then wscript.echo sc.name^&" - "^&sc.pathname >>sc.vbs
@echo next >>sc.vbs & cscript //nologo sc.vbs & del sc.vbs

7，顯示系統(tǒng)最后一次啟動的時間

@echo for each os in getobject _ >bt.vbs
@echo ("winmgmts:\\.\root\cimv2:win32_operatingsystem").instances_ >>bt.vbs
@echo wscript.echo os.lastbootuptime:next >>bt.vbs & cscript //nologo bt.vbs & del bt.vbs

以上是“CMD下如何配置網(wǎng)絡安全”這篇文章的所有內(nèi)容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內(nèi)容對大家有所幫助，如果還想學習更多知識，歡迎關(guān)注億速云行業(yè)資訊頻道！