如何用ntiiframe.vbs批量清除被添加到文件中的惡意代

本篇內(nèi)容介紹了“如何用ntiiframe.vbs批量清除被添加到文件中的惡意代”的有關(guān)知識(shí)，在實(shí)際案例的操作過(guò)程中，不少人都會(huì)遇到這樣的困境，接下來(lái)就讓小編帶領(lǐng)大家學(xué)習(xí)一下如何處理這些情況吧！希望大家仔細(xì)閱讀，能夠?qū)W有所成！

AntiIframe.vbs
#該腳本是批量掛馬程序的逆向，用于批量清除被添加到文件中的惡意代碼。記事本打開(kāi)文件可以修改Pattern參數(shù)指定要處理的文件名，文件名之間用|隔開(kāi)（也支持vbs正則表達(dá)式）。由于要修改文件，請(qǐng)謹(jǐn)慎的使用（最好先備份文件）
#用法: CScript AntiIframe.vbs [處理的路徑] [包含清除內(nèi)容的文件]
#例子: CScript AntiIframe.vbs d:\Web d:\lake2.txt

復(fù)制代碼 代碼如下:

'-----------------------
'Anti-Iframe in vbs
'Author: lake2 (http://lake2.0x54.org)
'Date:   2007-2-27
'Version: 1.1 
'-----------------------

'-------- Config Start --------------
'配置要處理的文件名，可使用vbs正則表達(dá)式；也可以使用“(index.asp|index.htm|index.html)”枚舉格式
Pattern = "^.+\.(htm|html|asp|aspx|php)$"
'-------- Config  End  --------------


Call ShowInfo()
If WScript.Arguments.Count = 2 Then
    If Right(WScript.Arguments.Item(0),1) = "\" Then
        if len(WScript.Arguments.Item(0))>3 then 
            thePath = Mid(WScript.Arguments.Item(0),1,Len(WScript.Arguments.Item(0))-1)
        else
            thePath = WScript.Arguments.Item(0)
        end if
    Else
        thePath = WScript.Arguments.Item(0)
    End If
    Call CheckArg(thePath)
    WScript.Echo "開(kāi)始清理，請(qǐng)稍候……"
    Call ShowAllFile(thePath)
    WScript.Echo vbcrlf & "清理完成！" & vbcrlf
Else
    Call ShowHelp()
End If

Sub ShowInfo()
    HelpStr = HelpStr & "=====＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝=====" & vbcrlf
    HelpStr = HelpStr & "=====  歡迎使用雷客圖 ASP 站長(zhǎng)安全助手vbs版  =====" & vbcrlf
    HelpStr = HelpStr & "=====       之  Anti-批量掛馬                =====" & vbcrlf
    HelpStr = HelpStr & "=====           Author: lake2                =====" & vbcrlf
    HelpStr = HelpStr & "=====       Email:lake2@mail.csdn.net        =====" & vbcrlf
    HelpStr = HelpStr & "=====   歡迎訪問(wèn) www.0x54.org 得到更多信息   =====" & vbcrlf
    HelpStr = HelpStr & "=====＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝=====" & vbcrlf
    HelpStr = HelpStr & vbcrlf
    WScript.Echo HelpStr
End Sub

Sub ShowHelp()
    HelpStr = HelpStr & "#用法: CScript AntiIframe.vbs [處理的路徑] [包含清除內(nèi)容的文件]" & vbcrlf
    HelpStr = HelpStr & "#例子: CScript AntiIframe.vbs d:\Web d:\lake2.txt" & vbcrlf
    HelpStr = HelpStr & vbcrlf
    WScript.Echo HelpStr
End Sub

Sub CheckArg(arg)
    tmpPath = arg
    Set objFSO = WScript.CreateObject ("Scripting.FileSystemObject")
    If Not objFSO.FileExists(WScript.Arguments.Item(1)) Then
        WScript.Echo "Error：未找到配置文件“" & WScript.Arguments.Item(1) & "”！"
        WScript.Quit
    ElseIf Not objFSO.FolderExists(tmpPath) Then
        WScript.Echo "Error：錯(cuò)誤的路徑“" & tmpPath & "”！"
        WScript.Quit    
    End If
    Set objFSO = Nothing
End Sub

'遍歷處理path及其子目錄所有文件
Sub ShowAllFile(Path)
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set g = FSO.GetFile(WScript.Arguments.Item(1))
    If g.Size > 0 Then
        Set ts2 = g.OpenAsTextStream(1, -2)
        filecon = ts2.ReadAll
        ts2.Close
        Set ts2 = Nothing
    Else
        WScript.Echo "Error：配置文件" & WScript.Arguments.Item(1) & "大小為0！"
        WScript.Quit
    End If
    Set g = Nothing
    Set f = FSO.GetFolder(Path)
    Set fc2 = f.files
    On Error Resume Next
    For Each myfile in fc2
        If Err Then WScript.Echo "權(quán)限不足，不能檢查目錄"&thePath:exit sub
        Set regEx = New RegExp
        regEx.IgnoreCase = True
        regEx.Global = True
        regEx.Pattern = Pattern
        If regEx.Test(myfile.name) Then
            CheckFile path&"\"&myfile.name, filecon
        End If
        Set regEx = Nothing        
    Next
    Set fc = f.SubFolders
    For Each f1 in fc
        ShowAllFile path&"\"&f1.name
        Next
    Set FSO = Nothing
End Sub

Sub CheckFile(filepath, filecon2)
    xSet = GetCharSet(filepath)
    Set tStream = CreateObject("ADODB.Stream")
    tStream.type = 1
    tStream.mode = 3
    tStream.open
    tStream.Position=0
    tStream.LoadFromFile FilePath
    If err Then Exit Sub end if
    tStream.type = 2
    tStream.charset = xSet
    Do Until tStream.EOS
        filecon = filecon & LCase(tStream.ReadText(102400))
    Loop
    tStream.close()
    Set tStream = Nothing
        If InStr(filecon, filecon2) > 0 Then
            filecon = Replace(filecon, filecon2, "")
            Set tStream = CreateObject("ADODB.Stream")
            tStream.type = 2
            tStream.mode = 3
            tStream.charset = xSet
            tStream.open
            tStream.Position=0
            tStream.WriteText filecon
            tStream.SaveToFile filepath, 2
            tStream.close()
            Set tStream = Nothing
            WScript.Echo "已經(jīng)修復(fù)文件: "&filepath&" ..."
        End If
End Sub

Function GetCharSet(xPath)
    Set tStream = CreateObject("ADODB.Stream")
    tStream.type = 1
    tStream.mode = 3
    tStream.open
    tStream.Position = 0
    tStream.LoadFromFile xPath
    byte1 = ascB(tStream.Read(1))
    byte2 = ascB(tStream.Read(1))
    byte3 = ascB(tStream.Read(1))
    tStream.close()
    Set tStream = Nothing
    If byte1=239 and byte2=187 and byte3=191 Then
        GetCharSet = "UTF-8"
    Else
        GetCharSet = "GB2312"
    End If
End Function

“如何用ntiiframe.vbs批量清除被添加到文件中的惡意代”的內(nèi)容就介紹到這里了，感謝大家的閱讀。如果想了解更多行業(yè)相關(guān)的知識(shí)可以關(guān)注億速云網(wǎng)站，小編將為大家輸出更多高質(zhì)量的實(shí)用文章！