CHM如何實(shí)現(xiàn)文檔解包批處理

這篇文章主要介紹CHM如何實(shí)現(xiàn)文檔解包批處理，文中介紹的非常詳細(xì)，具有一定的參考價(jià)值，感興趣的小伙伴們一定要看完！

HH的脾氣是目標(biāo)文件夾路徑不支持帶空格或引號(hào)，所以變復(fù)雜了點(diǎn)，否則一行命令足矣
其他的代碼沒(méi)啥難度，重在實(shí)用

批處理代碼如下：

代碼如下:

::主命令格式如下
::hh -decompile 目標(biāo)文件夾 CHM源文件名
::目標(biāo)文件夾及文件名均不能加引號(hào)，目標(biāo)文件夾不能含空格
@echo off & setlocal enabledelayedexpansion
title CHM 文檔解包批處理 By SunTB
if exist "%~dpnx1" (
set file=%~dpnx1
set file_pth=%~dp1
set file_pth=!file_pth:~0,-1!
set file_name=%~nx1
) else (
echo.&echo 請(qǐng)輸入 CHM 文件完整路徑：
echo.&set /p file=
set file=!file:"=!
call :pthquery
)
if /i not "!file:~-4!"==".chm" (echo.&echo 該文件類型名不是 .CHM ，按任意鍵退出&pause>nul&exit)
set save_pth=!file_name: =!
cd /d "!file_pth!"
hh -decompile !save_pth:~0,-4!_CHM !file_name!
start "" "!file_pth!\!save_pth:~0,-4!_CHM"
exit
::提取手工輸入路徑中的文件夾路徑及文件名
:pthquery
set /a pthx+=1
if "!file:~-%pthx%,1!"=="\" (
set file_pth=!file:~0,-%pthx%!
set file_name=!file:~-%pthx%!
set file_name=!file_name:~1!
goto :eof
)
goto :pthquery

以上是“CHM如何實(shí)現(xiàn)文檔解包批處理”這篇文章的所有內(nèi)容，感謝各位的閱讀！希望分享的內(nèi)容對(duì)大家有幫助，更多相關(guān)知識(shí)，歡迎關(guān)注億速云行業(yè)資訊頻道！