vbs中怎么對文本文件內(nèi)容進(jìn)行排序

vbs中怎么對文本文件內(nèi)容進(jìn)行排序，相信很多沒有經(jīng)驗的人對此束手無策，為此本文總結(jié)了問題出現(xiàn)的原因和解決方法，通過這篇文章希望你能解決這個問題。

問：
您好，腳本專家！我有一個包含計算機(jī)名稱列表的文本文件。如何按照字母順序?qū)υ撐募M(jìn)行排序？
-- LR
答：
您好，LR。如果想偷懶的話，我們就會告訴您：“對不起，您不能這樣做?！蔽覀円部梢跃痛嗣撋恚驗?nbsp;Microsoft 的腳本編寫技術(shù)中沒有一個方法能在打開文本文件后對文件進(jìn)行排序。不過，嗨，“腳本專家”什么時候偷過懶呢？
噢，對了，我們是偷過幾次懶，不過希望所有的人都已經(jīng)忘了。不過，這次我們將向您提供一個解決辦法。
雖然沒有能直接對文本文件進(jìn)行排序的方法，但我們可以通過執(zhí)行以下操作最終達(dá)到相同的效果：1) 使用 FileSystemObject 將文件讀取到內(nèi)存中；2) 在內(nèi)存中按照字母順序?qū)ξ募M(jìn)行排序；3) 使用內(nèi)存中的已排序的數(shù)據(jù)替換文件現(xiàn)有的內(nèi)容。這些操作雖然有點兒繞彎兒，但是您最后將得到一個已按照字母順序進(jìn)行排序的文本文件，而這正是您想要的結(jié)果。
為了完成此任務(wù)，我們選擇使用一個斷開連接的記錄集。還有其他的方法能夠?qū)崿F(xiàn)此目的（比如說，冒泡排序），但是斷開連接的記錄集能提供更多的靈活性，且更易于講解，尤其適合于那些曾有過數(shù)據(jù)庫編程經(jīng)驗的用戶。我們在此將向您簡要介紹斷開連接的記錄集；若要獲得有關(guān)其工作原理的詳細(xì)說明，您可能需要訪問 Scripting Week 2 網(wǎng)絡(luò)廣播 Things the Scripting Guys Never Told You（腳本專家從未告訴過您的事情）。（作為額外提供的補(bǔ)充信息，該網(wǎng)絡(luò)廣播還將向您說明如何使用冒泡排序?qū)蝹€文件數(shù)據(jù)進(jìn)行排序。）
在開始之前，我們假定您有一個與以下內(nèi)容類似的文本文件，文件的每一行都有一個計算機(jī)名稱：
red-ws-02
atl-ws-01
sf-ws-02
atl-ws-02
atl-ws-03
red-ws-02
sf-ws-01

如何讀取這些計算機(jī)名稱、對它們進(jìn)行排序并接著將排序后的列表寫回該文本文件呢？我們可以使用一個與以下內(nèi)容類似的腳本：
Const adVarChar = 200
Const MaxCharacters = 255
Const ForReading = 1
Const ForWriting = 2

Set DataList = CreateObject("ADOR.Recordset")
DataList.Fields.Append "ComputerName", adVarChar, MaxCharacters
DataList.Open

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("C:\Scripts\Computers.txt", ForReading)

Do Until objFile.AtEndOfStream
    strLine = objFile.ReadLine
    DataList.AddNew
    DataList("ComputerName") = strLine
    DataList.Update
Loop

objFile.Close

DataList.Sort = "ComputerName"

DataList.MoveFirst
Do Until DataList.EOF
    strText = strText & DataList.Fields.Item("ComputerName") & vbCrLf
    DataList.MoveNext
Loop

Set objFile = objFSO.OpenTextFile("C:\Scripts\Computers.txt", ForWriting)

objFile.WriteLine strText
objFile.Close

首先，我們定義要創(chuàng)建斷開連接的記錄集所需要的一系列常量。（應(yīng)將斷開連接的記錄集視為一個只存在于內(nèi)存中的、與儲存在磁盤驅(qū)動器上的物理數(shù)據(jù)庫無關(guān)的數(shù)據(jù)庫。）然后，我們使用以下這組代碼來創(chuàng)建一個由單個字段“ComputerName”組成的斷開連接的記錄集：
Set DataList = CreateObject("ADOR.Recordset")
DataList.Fields.Append "ComputerName", adVarChar, MaxCharacters
DataList.Open

接下來，我們使用 FileSystemObject 來打開文本文件 C:\Scripts\Computers.txt。此時，我們準(zhǔn)備開始對所創(chuàng)建的記錄集進(jìn)行填充。我們要執(zhí)行的操作就是逐行讀取該文本文件。每讀取一行，我們都將使用“AddNew”方法向記錄集添加一條新記錄。我們將 ComputerName 字段的值設(shè)置為我們剛才在該文本文件中讀取的行（請記住，該文本文件的各行分別表示一個計算機(jī)名稱），然后使用“Update”方法將記錄保存到該記錄集。繼續(xù)執(zhí)行此操作，直至我們讀取完該文本文件的每一行為止，然后我們將關(guān)閉該文件。 
是的，這聽起來好像工作量很大，但是正如您看到的，所有的操作只需以下幾行代碼：
Do Until objFile.AtEndOfStream
    strLine = objFile.ReadLine
    DataList.AddNew
    DataList("ComputerName") = strLine
    DataList.Update
Loop

objFile.Close

接下來，我們需要對記錄集進(jìn)行排序。這是使用斷開連接的記錄集而不使用冒泡排序或其他手動排序算法的主要好處之一。對記錄集進(jìn)行排序只需執(zhí)行一行代碼：
DataList.Sort = "ComputerName"

現(xiàn)在我們就有了一個已排序的記錄集，需要使用該記錄集將數(shù)據(jù)寫回文本文件。實現(xiàn)此目的最簡單的方法就是遍歷此記錄集、抓取每條記錄并將整個記錄集保存在一個變量中。這就是下面所執(zhí)行的操作：
DataList.MoveFirst
Do Until DataList.EOF
    strText = strText & DataList.Fields.Item("ComputerName") & vbCrLf
    DataList.MoveNext
Loop

我們只是看一看各行記錄，然后將 ComputerName 字段的值存儲在變量 strText 中。請注意我們是如何執(zhí)行此操作的：我們將 strText 的值設(shè)置為 strText 中的任何值加上當(dāng)前 ComputerName 字段的值，再加上一個回車換行符（這正是 vbCrLf 常量所表示的）。我們將使用內(nèi)存中的一個名為 strText 的變量來結(jié)束此操作，該變量包含以下數(shù)據(jù)：
atl-ws-01
atl-ws-02
atl-ws-03
red-ws-02
red-ws-02
sf-ws-01
sf-ws-02

最后，重新打開該文本文件（這次是為了寫入）并使用“WriteLine”方法將現(xiàn)有的內(nèi)容替換為 strText 的值。因為 strText 的值就是已排序的計算機(jī)名稱列表，所以我們就完成了對 C:\Scripts\Computers.txt 的內(nèi)容按照字母順序進(jìn)行的排序。

看完上述內(nèi)容，你們掌握vbs中怎么對文本文件內(nèi)容進(jìn)行排序的方法了嗎？如果還想學(xué)到更多技能或想了解更多相關(guān)內(nèi)容，歡迎關(guān)注億速云行業(yè)資訊頻道，感謝各位的閱讀！