批處理bat如何實(shí)現(xiàn)楊輝三角效果

這篇文章主要介紹了批處理bat如何實(shí)現(xiàn)楊輝三角效果，具有一定借鑒價(jià)值，感興趣的朋友可以參考下，希望大家閱讀完這篇文章之后大有收獲，下面讓小編帶著大家一起了解一下。

效果圖：

代碼如下:

@echo off&color 0e
setlocal enabledelayedexpansion
mode con: cols=130 lines=130
:top
cls
::set /p in=請(qǐng)輸入行數(shù)：
set in=23&set ab=1&set var=64
if "%in%"=="" goto top
if %in% geq 35 goto top
if %in% leq 0 goto top
echo %in%|findstr /r "^[0-9][0-9]*$">nul 2>nul||goto top
set str=1
for /l %%i in (1,1,%in%) do (
   set num=
   set num2=0
   for %%a in (!str!) do (
   set /a num2+=1
   if !num2!==1 set "str1="
   set /a num1=%%a+num
   set "str1=!str1! !num1!"
   set num=%%a
   )
   call :lis "!str1:~1!"
   set "str=!str1! 0"
)
rem 再輸出個(gè)倒 金字塔 玩玩。
for /l %%a in (22 -1 1) do echo !nam%%a!
for /l %%i in (1 1 3) do (
  for %%a in (a b c d e f) do (
  color 0%%a
  ping/n 2 127.1>nul
  ))
exit
:lis
set max=%~1
for /l %%a in (0 1 300) do (
if not "!max:~%%a,1!"=="" set /a ci+=1
)
set /a ki=var-ci/2
for /l %%a in (1 1 !ki!) do set kg= !kg!
echo !kg!!max!
set nam!ab!=!kg!!max!
set /a ab+=1
set ci=0&set kg=
goto :eof

感謝你能夠認(rèn)真閱讀完這篇文章，希望小編分享的“批處理bat如何實(shí)現(xiàn)楊輝三角效果”這篇文章對(duì)大家有幫助，同時(shí)也希望大家多多支持億速云，關(guān)注億速云行業(yè)資訊頻道，更多相關(guān)知識(shí)等著你來(lái)學(xué)習(xí)!