dos中如何用批處理刪除N天前或指定日期時間內(nèi)創(chuàng)建以及修改的文件

這篇文章給大家介紹dos中如何用批處理刪除N天前或指定日期時間內(nèi)創(chuàng)建以及修改的文件，內(nèi)容非常詳細(xì)，感興趣的小伙伴們可以參考借鑒，希望對大家能有所幫助。

核心代碼：

@echo off
:: by oicu#lsxk.org
:: 15:17 2011-1-13

:: 如果只是刪除指定日期或N天前修改的文件，用forfiles即可
FORFILES /P "C:\測試目錄" /S /M *.log /D -3 /C "cmd /c if @isdir==FALSE echo del @file"
:: 指定日期（包含）前修改的文件：/D -yyyy/mm/dd

:: 以下是流水賬
:: 使用限制：控制面板里設(shè)定日期格式為中文(中國)
:: 只有dir /tc才能查看到文件創(chuàng)建時間，默認(rèn)dir都是dir /tw
:: 為了取出創(chuàng)建時間，只好用兩次for+find，肯定很慢。

cd /d 你的目錄
:: 如果要包含子目錄，用for /r . %%a in (*)

:: 顯示文件修改時間
for %%a in (*) do echo "%%~ta"
:: 中文格式時相當(dāng)于
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tw "%%a" ^| find /i "%%~nxa"'
) do echo "%%b %%c"

:: 刪除某個時間后修改過的文件(這個簡單)
for %%a in (*) do if "%%~ta" gtr "2008-04-01" echo del "%%a"

:: 這個才是顯示文件創(chuàng)建時間
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tc "%%a" ^| find /i "%%~nxa"'
) do echo "%%b %%c"

:: 刪除某個時間之后創(chuàng)建的文件，如果要刪除某個時間之前創(chuàng)建的，更改兩
:: 處gtr為lss。除了日期外，增加判斷時間，可以去掉else段。
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tc "%%a" ^| find /i "%%~nxa"') do (
  if "%%b" gtr "2010-12-15" (
    echo del "%%a"
  ) else (
    if "%%b" equ "2010-12-15" if "%%c" gtr "14:50" echo del "%%a"
  )
)

:: 用批處理計算時間受到系統(tǒng)的日期格式限制，影響到用set取某一字段的值，
:: 批處理計算時間方法過于復(fù)雜，要么只用vbs腳本刪除文件，要么用批處理
:: 配合vbs腳本刪除。

:: 取10天之前的日期，取回放入變量OldDate
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f %%a in ('cscript /nologo GetOldDate.vbs') do set OldDate=%%a
echo %OldDate%
del GetOldDate.vbs

:: VBScript里沒有Format函數(shù)，Year、Month、Day等函數(shù)取數(shù)值后也要處理小
:: 于10的數(shù)字，只能用下面的方法整理日期格式
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f "tokens=1,2,3* delims=-/. " %%i in ('cscript /nologo GetOldDate.vbs') do (
  set y=%%i
  set m=%%j
  set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set OldDate=%y%-%m%-%d%
echo %OldDate%
del GetOldDate.vbs


:: 綜合上文，最后得到我們想要的結(jié)果
:: 刪除10天前創(chuàng)建的舊文件(不含子目錄)
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f "tokens=1,2,3* delims=-/. " %%i in ('cscript /nologo GetOldDate.vbs') do (
  set y=%%i
  set m=%%j
  set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set OldDate=%y%-%m%-%d%
del GetOldDate.vbs
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tc "%%a" ^| find /i "%%~nxa"') do (
  if "%%b" lss "%OldDate%" echo del "%%a"
)

:: 刪除10天前修改的舊文件(不含子目錄)
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f "tokens=1,2,3* delims=-/. " %%i in ('cscript /nologo GetOldDate.vbs') do (
  set y=%%i
  set m=%%j
  set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set OldDate=%y%-%m%-%d%
del GetOldDate.vbs
for %%a in (*) do if "%%~ta" lss "%OldDate%" echo del "%%a"


:: 本文全部用echo del代替del，只是顯示要刪除的文件，并不實際刪除。

pause
goto :eof

關(guān)于dos中如何用批處理刪除N天前或指定日期時間內(nèi)創(chuàng)建以及修改的文件就分享到這里了，希望以上內(nèi)容可以對大家有一定的幫助，可以學(xué)到更多知識。如果覺得文章不錯，可以把它分享出去讓更多的人看到。