VBS中如何使用Default關(guān)鍵字

今天就跟大家聊聊有關(guān)VBS中如何使用Default關(guān)鍵字，可能很多人都不太了解，為了讓大家更加了解，小編給大家總結(jié)了以下內(nèi)容，希望大家根據(jù)這篇文章可以有所收獲。

其實(shí) MSDN 的 VBScript 文檔中關(guān)于 Function 和 Sub 語(yǔ)句的部分提到過(guò) Default 關(guān)鍵字：

Default
Used only with the Public keyword in a Class block to indicate that the Function procedure is the default method for the class. An error occurs if more than one Default procedure is specified in a class.

Default 只能在 Class 語(yǔ)句塊中與 Public 關(guān)鍵字一起使用來(lái)表明函數(shù)過(guò)程是類(lèi)的默認(rèn)方法。如果類(lèi)中一個(gè)以上的過(guò)程被定義為 Default，那么會(huì)出現(xiàn)錯(cuò)誤。
一個(gè)簡(jiǎn)單的例子：

Class MyClass 

Public Default Function SayHello(name)
SayHello = "Hello, " & name
End Function
End Class
Set o = New MyClass
MsgBox o("demon")

很多面向?qū)ο蟮恼Z(yǔ)言都能使用構(gòu)造函數(shù)來(lái)初始化類(lèi)的對(duì)象，但是 VBS 卻沒(méi)有構(gòu)造函數(shù)的概念，只是提供了一個(gè)類(lèi)初始化事件來(lái)初始化對(duì)象：

Class TestClass 

' Setup Initialize event.
Private Sub Class_Initialize
MsgBox("TestClass started")
End Sub
' Setup Terminate event.
Private Sub Class_Terminate
MsgBox("TestClass terminated")
End Sub
End Class
' Create an instance of TestClass.
Set X = New TestClass
' Destroy the instance.
Set X = Nothing

雖然看起來(lái)很像構(gòu)造函數(shù)，但是卻不能帶參數(shù)，沒(méi)有辦法像其他語(yǔ)言那樣用特定的參數(shù)來(lái)初始化對(duì)象。
有了 Default 關(guān)鍵字之后，我們可以模擬實(shí)現(xiàn)構(gòu)造函數(shù)的功能：

復(fù)制代碼 代碼如下:

'Author: Demon
'Date: 2011/09/29
'Website: http://demon.tw
Class Rectangle
Private height, width
Public Default Function Construtor(h, w)
height = h : width = w
Set Construtor = Me
End Function
Public Property Get Area
Area = height * width
End Property
End Class
'看起來(lái)是不是很像構(gòu)造函數(shù)呢
Set r = (New Rectangle)(6, 8)
MsgBox r.Area

看完上述內(nèi)容，你們對(duì)VBS中如何使用Default關(guān)鍵字有進(jìn)一步的了解嗎？如果還想了解更多知識(shí)或者相關(guān)內(nèi)容，請(qǐng)關(guān)注億速云行業(yè)資訊頻道，感謝大家的支持。