php中phpsh hpcli開發(fā)的示例分析

這篇文章給大家分享的是有關(guān)php中phpsh hpcli開發(fā)的示例分析的內(nèi)容。小編覺得挺實(shí)用的，因此分享給大家做個(gè)參考，一起跟隨小編過來看看吧。

最近用php代替vbs腳本，做些小工具的開發(fā)。為了方便測試不同php版本的兼容，專門寫了一個(gè) php版本切換的 批處理 phpsh.cmd，支持安裝到系統(tǒng)、卸載等功能，還支持多個(gè)php版本的任意切換（需要先安裝phpStudy）。

如果需要安裝到系統(tǒng)，必須以管理員身份運(yùn)行 命令提示符，基本的使用方法如下：

安裝成功后，就不用使用管理員身份執(zhí)行了?？梢栽谌我饽夸?執(zhí)行 phpsh，會(huì)自動(dòng)設(shè)置php環(huán)境。

如果以 非管理員身份執(zhí)行 安裝和卸載，會(huì)有對應(yīng)的提示。不安裝到系統(tǒng)也可以運(yùn)行：

不安裝時(shí)，如果phpsh沒有在當(dāng)前路徑，可以使用完整的路徑名運(yùn)行：

代碼比較簡單，下面時(shí)全部的代碼：

@echo off
 
::安裝路徑
set ins=C:\Windows\%~nx0
 
::如果存在對應(yīng)的PHP版本，進(jìn)入主程序
if "%1"=="" goto main
if "%1"=="52" goto main
if "%1"=="53" goto main
if "%1"=="53n" goto main
if "%1"=="55" goto main
if "%1"=="55n" goto main
if "%1"=="70n" goto main
goto cmds
 
::主程序
:main
set PHP_VER=PHP%1
if "%PHP_VER%" == "PHP" set PHP_VER=PHP55
set path=d:\phpstudy\%PHP_VER%;%path%
title %PHP_VER%_sh
prompt %PHP_VER%_sh^>$p#
goto quit
 
::如果是輸入的非數(shù)字參數(shù)，解析
:cmds
if "%1"=="/i" goto install
if "%1"=="/install" goto install
if "%1"=="/u" goto uninstall
if "%1"=="/uninstall" goto uninstall
if "%1"=="/v" goto version
if "%1"=="/version" goto version
goto help
 
::顯示幫助
:help
echo 用法: %~n0 [/h ^| /help ^| /i ^| /install ^| /u ^| /unstall ^| /v ^| /version ^| PHP_VERSION]
echo.
echo  沒有參數(shù)  設(shè)置php版本為php5.5
echo  /h     顯示幫助
echo  /help   顯示幫助，和/h相同
echo  /i     安裝到系統(tǒng)
echo  /install  安裝到系統(tǒng)，和/i相同
echo  /u     卸載
echo  /unstall  卸載，同/u
echo  /v     查看當(dāng)前php版本
echo  /version  查看當(dāng)前php版本，同/u
echo  52     設(shè)置php版本為php5.2
echo  53     設(shè)置php版本為php5.3
echo  53n    設(shè)置php版本為php5.3n
echo  55     設(shè)置php版本為php5.5
echo  55n    設(shè)置php版本為php5.5n
echo  70n    設(shè)置php版本為php7.0n
goto quit
 
::查看版本
:version
php --version
goto quit
 
::安裝
:install
echo 開始安裝..
if not exist %ins% copy %~f0 %ins%>nul
if %ERRORLEVEL% == 0 echo 安裝成功，打開命令提示符后輸入%~n0即可啟動(dòng)
if %ERRORLEVEL% == 1 echo 安裝失敗，必須以管理員模式運(yùn)行
goto quit
 
::卸載失敗
:uninstallerror
echo 卸載失敗，必須以管理員模式運(yùn)行
goto quit
 
::卸載
:uninstall
copy %~f0 %ins%.bak>nul
if %ERRORLEVEL% == 1 goto uninstallerror
echo 卸載成功
del %ins%.bak>nul
if exist %ins% del %ins%
 
:quit

php是什么語言

php，一個(gè)嵌套的縮寫名稱，是英文超級(jí)文本預(yù)處理語言（PHP:Hypertext Preprocessor）的縮寫。PHP 是一種 HTML 內(nèi)嵌式的語言，PHP與微軟的ASP頗有幾分相似，都是一種在服務(wù)器端執(zhí)行的嵌入HTML文檔的腳本語言，語言的風(fēng)格有類似于C語言，現(xiàn)在被很多的網(wǎng)站編程人員廣泛的運(yùn)用。

感謝各位的閱讀！關(guān)于“php中phpsh hpcli開發(fā)的示例分析”這篇文章就分享到這里了，希望以上內(nèi)容可以對大家有一定的幫助，讓大家可以學(xué)到更多知識(shí)，如果覺得文章不錯(cuò)，可以把它分享出去讓更多的人看到吧！