VBScript如何監(jiān)控并結(jié)束指定進(jìn)程

這篇文章主要為大家展示了“VBScript如何監(jiān)控并結(jié)束指定進(jìn)程”，內(nèi)容簡而易懂，條理清晰，希望能夠幫助大家解決疑惑，下面讓小編帶領(lǐng)大家一起研究并學(xué)習(xí)一下“VBScript如何監(jiān)控并結(jié)束指定進(jìn)程”這篇文章吧。

運(yùn)行效果圖：

代碼（monprocess.vbs）：

復(fù)制代碼 代碼如下:

On Error Resume Next

strComputer = "."
arrTargetProcs = Array("calc.exe", "notepad.exe", "other.exe")
'數(shù)組里為要監(jiān)視的進(jìn)程名

Set SINK = WScript.CreateObject("WbemScripting.SWbemSink","SINK_")
Set objWMIService = GetObject("winmgmts:" & _
 "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
objWMIService.ExecNotificationQueryAsync SINK, _
 "SELECT * FROM __InstanceCreationEvent WITHIN 1 " & _
  "WHERE TargetInstance ISA 'Win32_Process'"
Wscript.Echo "Are monitoring processes ..."
Do
 WScript.Sleep 1000
Loop

'***************************************************************************
Sub SINK_OnObjectReady(objLatestEvent, objAsyncContext)
'Trap asynchronous events.
 For Each strTargetProc In arrTargetProcs
  If LCase(objLatestEvent.TargetInstance.Name) = LCase(strTargetProc) Then
   intReturn = objLatestEvent.TargetInstance.Terminate
   If intReturn = 0 Then
    Wscript.Echo "Time: " & Now & ", Succeed!" & chr(9) & _
     "Name: " & objLatestEvent.TargetInstance.Name
    Else
    Wscript.Echo "Time: " & Now & ", Failed!" & chr(9) & _
     "Name: " & objLatestEvent.TargetInstance.Name
   End If
  End If
 Next
End Sub

以上是“VBScript如何監(jiān)控并結(jié)束指定進(jìn)程”這篇文章的所有內(nèi)容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內(nèi)容對大家有所幫助，如果還想學(xué)習(xí)更多知識，歡迎關(guān)注億速云行業(yè)資訊頻道！